(VBScript) Walmart - Update bulk inventory

See Update bulk inventory for more information about this call.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Sends the following POST request:
' POST https://marketplace.walmartapis.com/v2/feeds?feedType=inventory

url = "https://marketplace.walmartapis.com/v2/feeds?feedType=inventory"

requestMethod = "POST"

' First we need to generate a signature for our request.
' The signature needs to be re-generated for each new Walmart HTTP request.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthUtil")
set authUtil = CreateObject("Chilkat.AuthUtil")

wmConsumerId = "WALMART_CONSUMER_ID"
wmPrivateKey = "WALMART_PRIVATE_KEY"
jsonStr = authUtil.WalmartSignature(url,wmConsumerId,wmPrivateKey,requestMethod)
If (authUtil.LastMethodSuccess <> 1) Then
    outFile.WriteLine(authUtil.LastErrorText)
    WScript.Quit
End If

' Build the HTTP POST request.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "/v2/feeds?feedType=inventory"
req.AddHeader "Accept","application/xml"

' The JSON returned by WalmartSignature contains the values to be used in the following
' header fields: WM_SEC.AUTH_SIGNATURE, WM_SEC.TIMESTAMP, and WM_QOS.CORRELATION_ID
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(jsonStr)

req.AddHeader "WM_SVC.NAME","Walmart Marketplace"
req.AddHeader "WM_QOS.CORRELATION_ID",json.StringOf("correlation_id")
req.AddHeader "WM_SEC.TIMESTAMP",json.StringOf("timestamp")
req.AddHeader "WM_SEC.AUTH_SIGNATURE",json.StringOf("signature")
req.AddHeader "WM_CONSUMER.ID",wmConsumerId
'  Note: Make sure to replace "WALMART_CHANNEL_TYPE" with the actual value for your seller account...
req.AddHeader "WM_CONSUMER.CHANNEL.TYPE","WALMART_CHANNEL_TYPE"

' The body of the POST will contain XML.  In this example, we'll load the XML
' from a file.  The XML contains inventory data that looks something like this:

' <InventoryFeed xmlns="http://walmart.com/">
'   <InventoryHeader>
'       <version>1.4</version>
'   </InventoryHeader>
'   <inventory>
'       <sku>1068155</sku>
'       <quantity>
'           <unit>EACH</unit>
'           <amount>10</amount>
'       </quantity>
'       <fulfillmentLagTime>1</fulfillmentLagTime>
'   </inventory>
'   <inventory>
'       <sku>10210321</sku>
'       <quantity>
'           <unit>EACH</unit>
'           <amount>20</amount>
'       </quantity>
'       <fulfillmentLagTime>3</fulfillmentLagTime>
'   </inventory>
' </InventoryFeed>

success = req.AddFileForUpload2("inventory","qa_data/walmart/inventory.xml","application/xml")
If (success <> 1) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest("marketplace.walmartapis.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(resp.BodyStr)

' A successful response should have a 200 response status
If (resp.StatusCode <> 200) Then
    outFile.WriteLine(xml.GetXml())
    outFile.WriteLine("Response Status Code: " & resp.StatusCode)
    outFile.WriteLine("Failed.")

    WScript.Quit
End If

' Show the XML response..
outFile.WriteLine(xml.GetXml())
outFile.WriteLine("--")
outFile.WriteLine("Success!")

outFile.Close