(VBScript) Walmart - Get All Feed Statuses

Note: This is an older example for the Walmart v2 API. You should instead use the Walmart v3 API.

Demonstrates how to send a Walmart REST API request to get all feed statuses.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' --------------------------------------------------------------------
' This example is for the older and deprecated Walmart v2 API.
' 
' Use the v3 API instead: Walmart v3 Get All Feed Statuses
' --------------------------------------------------------------------

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Demonstrates how to send a request such as the following to get all feed statuses:
' Also demonstrates how to parse the results.

' GET /v2/feeds HTTP/1.1
' WM_SVC.NAME: Walmart Marketplace
' WM_QOS.CORRELATION_ID: 123456abcdef
' WM_SEC.TIMESTAMP: 1438147839
' WM_SEC.AUTH_SIGNATURE: 9khb0lPeRt0WSGbXNGGj4kSQ9L6PMBX/q+ovdy9bDQfvdhYs8NoEsjRX4fD7UNIHTddgkmSVqAqeIIHlaLcRIl0Y4DcJqQYHL27LiWlsm91nYodGssWTKsOq6dJfUHEy95M4zXFGWDDhbHYCor28SCV/g/JdEQybGkcX9Zj5aDyg=
' WM_CONSUMER.ID: a20ac266-9add-4fc7-9392-fec303f5155c
' Accept: application/xml
' Host: https://marketplace.walmartapis.com

requestUrl = "https://marketplace.walmartapis.com/v2/feeds"
requestMethod = "GET"

' First we need to generate a signature for our request.
' The signature needs to be re-generated for each new Walmart HTTP request.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthUtil")
set authUtil = CreateObject("Chilkat.AuthUtil")

wmConsumerId = "WALMART_CONSUMER_ID"
wmPrivateKey = "WALMART_PRIVATE_KEY"
jsonStr = authUtil.WalmartSignature(requestUrl,wmConsumerId,wmPrivateKey,requestMethod)
If (authUtil.LastMethodSuccess <> 1) Then
    outFile.WriteLine(authUtil.LastErrorText)
    WScript.Quit
End If

' The JSON returned by WalmartSignature contains the values to be used in the following
' header fields: WM_SEC.AUTH_SIGNATURE, WM_SEC.TIMESTAMP, and WM_QOS.CORRELATION_ID
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(jsonStr)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
http.SetRequestHeader "WM_SVC.NAME","Walmart Marketplace"
http.SetRequestHeader "WM_QOS.CORRELATION_ID",json.StringOf("correlation_id")
http.SetRequestHeader "WM_SEC.TIMESTAMP",json.StringOf("timestamp")
http.SetRequestHeader "WM_SEC.AUTH_SIGNATURE",json.StringOf("signature")
http.SetRequestHeader "WM_CONSUMER.ID",wmConsumerId
http.Accept = "application/xml"

' Note: Do not explicitly set the "Host" header.  Chilkat will set it automatically.

xmlStr = http.QuickGetStr(requestUrl)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(xmlStr)

' A successful response should have a 200 response status
If (http.LastStatus <> 200) Then
    outFile.WriteLine(xml.GetXml())
    outFile.WriteLine("Response Status Code: " & http.LastStatus)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' A sample XML response is shown below..

' To iterate over the Walmart feeds:
numFeeds = xml.NumChildrenAt("ns2:results")
i = 0
Do While i < numFeeds
    xml.I = i

    outFile.WriteLine("Feed ID: " & xml.GetChildContent("ns2:results|ns2:feed[i]|ns2:feedId"))
    outFile.WriteLine("Feed Type: " & xml.GetChildContent("ns2:results|ns2:feed[i]|ns2:feedType"))
    outFile.WriteLine("Num Items Recieved: " & xml.GetChildIntValue("ns2:results|ns2:feed[i]|ns2:itemsReceived"))
    outFile.WriteLine("Feed Status: " & xml.GetChildContent("ns2:results|ns2:feed[i]|ns2:feedStatus"))
    outFile.WriteLine("--")

    i = i + 1
Loop

outFile.WriteLine("Success.")

' ---------------------------------------
' Sample XML response
' ---------------------------------------

' <?xml version="1.0" encoding="UTF-8" standalone="yes" ?>
' <ns2:list xmlns:ns2="http://walmart.com/">
'     <ns2:totalResults>1293</ns2:totalResults>
'     <ns2:offset>0</ns2:offset>
'     <ns2:limit>50</ns2:limit>
'     <ns2:results>
'         <ns2:feed>
'             <ns2:feedId>AAAA7F0345E9403C91223F7139FFC341@AQsBAQA</ns2:feedId>
'             <ns2:feedType>inventory</ns2:feedType>
'             <ns2:partnerId>10000999999</ns2:partnerId>
'             <ns2:itemsReceived>130088</ns2:itemsReceived>
'             <ns2:itemsSucceeded>113154</ns2:itemsSucceeded>
'             <ns2:itemsFailed>16934</ns2:itemsFailed>
'             <ns2:itemsProcessing>0</ns2:itemsProcessing>
'             <ns2:feedStatus>PROCESSED</ns2:feedStatus>
'             <ns2:feedDate>2017-04-27T17:05:42.078Z</ns2:feedDate>
'             <ns2:modifiedDtm>2017-04-27T18:06:10.795Z</ns2:modifiedDtm>
'         </ns2:feed>
'         <ns2:feed>
'             <ns2:feedId>AAAAF1F402CD407FA363AD2929593FFF@AQsBAQA</ns2:feedId>
'             <ns2:feedType>inventory</ns2:feedType>
'             <ns2:partnerId>10000999999</ns2:partnerId>
'             <ns2:itemsReceived>39594</ns2:itemsReceived>
'             <ns2:itemsSucceeded>34533</ns2:itemsSucceeded>
'             <ns2:itemsFailed>5061</ns2:itemsFailed>
'             <ns2:itemsProcessing>0</ns2:itemsProcessing>
'             <ns2:feedStatus>PROCESSED</ns2:feedStatus>
'             <ns2:feedDate>2017-04-27T05:18:59.739Z</ns2:feedDate>
'             <ns2:modifiedDtm>2017-04-27T05:20:30.192Z</ns2:modifiedDtm>
'         </ns2:feed>
' ...
'     </ns2:results>
' </ns2:list>

outFile.Close