(VBScript) Validate the at_hash Claim of an ID Token

Demonstrates how to hash an access token to compare it with the at_hash claim of an ID token.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a Google access_token + id_token that looks like this:

'  {
'   "access_token": "ya29.a0...0f",
'   "expires_in": 3599,
'   "scope": "openid https://www.googleapis.com/auth/userinfo.email",
'   "token_type": "Bearer",
'   "id_token": "eyJhb...o5nQ"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/google_sample_id_token.json")
If (success = 0) Then
    outFile.WriteLine("Failed to load the JSON file...")
    WScript.Quit
End If

' Use Chilkat's JWT API to examine the id_token..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jwt")
set jwt = CreateObject("Chilkat.Jwt")
idToken = jsonToken.StringOf("id_token")

' Extract the JOSE header..
jose = jwt.GetHeader(idToken)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonHeader = CreateObject("Chilkat.JsonObject")
success = jsonHeader.Load(jose)
jsonHeader.EmitCompact = 0
outFile.WriteLine(jsonHeader.Emit())

' The JOSE header looks like this:

' {
'   "alg": "RS256",
'   "kid": "e8799db06287515556213c80acbcfd022fb302a9",
'   "typ": "JWT"
' }

claims = jwt.GetPayload(idToken)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonClaims = CreateObject("Chilkat.JsonObject")
success = jsonClaims.Load(claims)
jsonClaims.EmitCompact = 0
outFile.WriteLine(jsonClaims.Emit())

' The claims look like this:

' {
'   "iss": "https://accounts.google.com",
'   "azp": "258999997753-5ni8lu5f15r7mno97d82f5lir9i9f6i1.apps.googleusercontent.com",
'   "aud": "258999997753-5ni8lu5f15r7mno97d82f5lir9i9f6i1.apps.googleusercontent.com",
'   "sub": "111787341816486547572",
'   "email": "somebody@gmail.com",
'   "email_verified": true,
'   "at_hash": "HYJZImlW3mUK-UfjRfXjKw",
'   "iat": 1615315968,
'   "exp": 1615319568
' }

' The at_hash is the Access Token hash value. Its value is the base64url encoding of the
' left-most half of the hash of the octets of the ASCII representation of the access_token value,
' where the hash algorithm used is the hash algorithm used in the alg Header Parameter of the
' ID Token's JOSE Header. For instance, if the alg is RS256, hash the access_token value with SHA-256,
' then take the left-most 128 bits and base64url encode them. The at_hash value is a case sensitive string.

token_to_hash = jsonToken.StringOf("access_token")
token_hash_expected = jsonClaims.StringOf("at_hash")

' Step 1. hashes the access token using SHA-256 (Google uses `RS256` as the ID Token `alg`).
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdHash = CreateObject("Chilkat.BinData")

crypt.HashAlgorithm = "sha256"
' This encoding mode must match the encoding mode passed in the 2nd arg to AppendEncoded.
' The encoding mode can be anything, as long as they are the same in both places.
crypt.EncodingMode = "hex"

success = bdHash.AppendEncoded(crypt.HashStringENC(token_to_hash),"hex")
sz = bdHash.NumBytes

token_hash_computed = bdHash.GetEncodedChunk(0,sz / 2,"base64url")

' If the hashes are identical, then the access_token as issued for the given id_token.
outFile.WriteLine("token_hash_expected: " & token_hash_expected)
outFile.WriteLine("token_hash_computed: " & token_hash_computed)

outFile.Close