(VBScript) Asynchronous HTTPS Upload (TLS)

Demonstrates how to do an HTTPS (TLS) upload asynchronously in a background thread.

A server-side C# example showing how to receive an upload is located at C# ASP.NET Code to Receive Upload

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Upload")
set upload = CreateObject("Chilkat.Upload")

' Specify the page (ASP, ASP.NET, Perl, Python, Ruby, CGI, etc)
' that will process the HTTP Upload.
upload.Hostname = "www.mywebserver.com"
upload.Path = "/receiveUpload.aspx"

' Add one or more files to be uploaded.
upload.AddFileReference "file1","dude.gif"
upload.AddFileReference "file2","pigs.xml"
upload.AddFileReference "file3","sample.doc"

' To upload using SSL/TLS (https), set the Ssl property = 1
upload.Ssl = 1

' Begin the HTTP upload in a background thread:
success = upload.BeginUpload()
If (success <> 1) Then
    outFile.WriteLine(upload.LastErrorText)
Else
    outFile.WriteLine("Upload started..")
End If

' Wait for the upload to finish.
' Print the progress as we wait...
Do While (upload.UploadInProgress = 1)
    ' We can abort the upload at any point by calling:
    ' upload.AbortUpload();

    ' Display the percentage complete and the number of bytes uploaded so far..
    ' The total upload size will become set after the upload begins:
    outFile.WriteLine(upload.PercentUploaded & "% " & upload.NumBytesSent & "/" & upload.TotalUploadSize)

    ' Sleep 2/10ths of a second.
    upload.SleepMs 200

Loop

' Did the upload succeed?
If (upload.UploadSuccess = 1) Then
    outFile.WriteLine("Files uploaded!")
Else
    outFile.WriteLine(upload.LastErrorText)
End If


outFile.Close