(VBScript) Upload Media to Twitter

Demonstrates uploading image or video files to Twitter. After uploading, the media_id can be used to attach the uploaded media to a tweet.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Assume we've previously obtained an access token and saved it to a JSON file..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/twitter.json")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Provide the OAuth 1.0a credentials:
http.OAuth1 = 1
http.OAuthConsumerKey = "TWITTER_CONSUMER_KEY"
http.OAuthConsumerSecret = "TWITTER_CONSUMER_SECRET"
http.OAuthToken = jsonToken.StringOf("oauth_token")
http.OAuthTokenSecret = jsonToken.StringOf("oauth_token_secret")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "/1.1/media/upload.json"

req.AddHeader "Expect","100-continue"

' Add a JPEG image file to the upload.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")

jpgBytes = fac.ReadEntireFile("qa_data/jpg/starfish.jpg")
success = req.AddBytesForUpload("media","starfish.jpg",jpgBytes)

' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest("upload.twitter.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResponse = CreateObject("Chilkat.JsonObject")
jsonResponse.EmitCompact = 0
success = jsonResponse.Load(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    outFile.WriteLine(jsonResponse.Emit())
    WScript.Quit
End If

' Show the successful response:
outFile.WriteLine(jsonResponse.Emit())
outFile.WriteLine("Success.")

' A successful JSON response looks like this:

' 	{
' 	  "media_id": 793137045996646400,
' 	  "media_id_string": "793137045996646400",
' 	  "size": 6229,
' 	  "expires_after_secs": 86400,
' 	  "image": {
' 	    "image_type": "image\/jpeg",
' 	    "w": 120,
' 	    "h": 120
' 	  }
' 	}
' 

' Get the information from the JSON:
outFile.WriteLine("media_id_string = " & jsonResponse.StringOf("media_id_string"))
outFile.WriteLine("size = " & jsonResponse.IntOf("size"))
outFile.WriteLine("image_type = " & jsonResponse.StringOf("image.image_type"))
outFile.WriteLine("height/width = " & jsonResponse.IntOf("image.w") & "," & jsonResponse.IntOf("image.h"))

outFile.Close