(VBScript) Load Certs from Java KeyStore into Trusted CA Roots

Demonstrates how to load a Java KeyStore containing CA root certificates that are to be trusted by the application. This can be done once at the beginning of an application, and then the trusted roots can be activated so that only these root CA certs are trusted by the application for any TLS connections.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JavaKeyStore")
set jks = CreateObject("Chilkat.JavaKeyStore")
jks.VerboseLogging = 1

password = "myPassword"
success = jks.LoadFile(password,"qa_data/jks/entrust_caCerts.jks")
If (success <> 1) Then
    outFile.WriteLine(jks.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.TrustedRoots")
set troots = CreateObject("Chilkat.TrustedRoots")
troots.VerboseLogging = 1

success = troots.AddJavaKeyStore(jks)
If (success <> 1) Then
    outFile.WriteLine(troots.LastErrorText)
    WScript.Quit
End If

i = 0
numCerts = troots.NumCerts
Do While (i < numCerts)
    ' cacert is a Chilkat.Cert
    Set cacert = troots.GetCert(i)
    outFile.WriteLine(i & ": " & cacert.SubjectDN)

    i = i + 1
Loop

' Activate this specific set of trusted roots.
success = troots.Activate()
If (success <> 1) Then
    outFile.WriteLine(troots.LastErrorText)
    WScript.Quit
End If

' Output:

' 0: C=US, O=Entrust.net, OU=www.entrust.net/CPS incorp. by ref. (limits liab.), OU=(c) 1999 Entrust.net Limited, CN=Entrust.net Secure Server Certification Authority
' 1: O=Entrust.net, OU=www.entrust.net/CPS_2048 incorp. by ref. (limits liab.), OU=(c) 1999 Entrust.net Limited, CN=Entrust.net Certification Authority (2048)
' 2: C=US, O="Entrust, Inc.", OU=www.entrust.net/CPS is incorporated by reference, OU="(c) 2006 Entrust, Inc.", CN=Entrust Root Certification Authority

outFile.Close