VBScript

Get Contents of a T-Mobile Text Message (as Email)

See more Email Object Examples

How to get the contents of an email that originated as a T-Mobile SMS text.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' First, for the purpose of understanding the structure of the MIME,
' let's load the MIME into a Chilkat MIME object and examine the MIME structure.
set mime = CreateObject("Chilkat.Mime")

success = mime.LoadMimeFile("qa_data/eml/TMobileTextMsg.eml")
' Show the MIME structure in text format (as opposed to XML format).
outFile.WriteLine(mime.GetStructure("text"))

' The MIME structure for our test email looks like this:
' multipart/related
'     text/html
'     text/plain
'     image/gif
'     image/gif
'     image/gif

' The HTML part is not considered a "related item" because the related items
' are defined as being related to the HTML part.  Therefore, we should always
' expect to find a text/html part under a multipart/related.  The HTML parts
' is simply the HTML body, and the other parts are the related items.
' If the text/plain part was to be considered as an alternative body,
' then a properly structured email would include a multipart/alternative structure.

set email = CreateObject("Chilkat.Email")

success = email.LoadEml("qa_data/eml/TMobileTextMsg.eml")

' We should see 4 related items.
outFile.WriteLine("Num Related Items = " & email.NumRelatedItems)
' There should be 0 attachments.  
outFile.WriteLine("Num Attachments = " & email.NumAttachments)

' Find the indices of the text/plain related part, and the text/html related part
i = 0
numRelatedItems = email.NumRelatedItems
set sbContentType = CreateObject("Chilkat.StringBuilder")
Do While i < numRelatedItems
    success = sbContentType.Append(email.GetRelatedContentType(i))
    outFile.WriteLine(i & ": " & sbContentType.GetAsString())
    If (sbContentType.ContentsEqual("text/plain",0)) Then
        outFile.WriteLine("---- text/plain part:")
        outFile.WriteLine(email.GetRelatedString(i,"utf-8"))
    End If

    sbContentType.Clear 
    i = i + 1
Loop

outFile.Close