VBScript

TicketBAI -- Send HTTP POST

See more TicketBAI Examples

Demonstrates how to send a TicketBAI POST and get the response. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

success = http.SetSslClientCertPfx("your.pfx","pfx_password")
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Get the XML we wish to send in the body of the request.
set sbXml = CreateObject("Chilkat.StringBuilder")
success = sbXml.LoadFile("qa_data/payload.xml","utf-8")
If (success = 0) Then
    outFile.WriteLine("Failed to load XML that is to be the HTTP request body")
    WScript.Quit
End If

' Build the following JSON

' { 
'     "con": "LROE", 
'     "apa": "1.1", 
'     "inte": { 
'         "nif": "número de identificación fiscal", 
'         "nrs": "nombre o Razón social", 
'         "ap1": "primer apellido", 
'         "ap2": "segundo apellido" 
'     }, 
'     "drs": { 
'     "mode": "140", 
'     "ejer": "ejercicio" 
'     } 
' }

' Use this online tool to generate code from sample JSON: 
' Generate Code to Create JSON

set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("con","LROE")
success = json.UpdateString("apa","1.1")
success = json.UpdateString("inte.nif","número de identificación fiscal")
success = json.UpdateString("inte.nrs","nombre o Razón social")
success = json.UpdateString("inte.ap1","primer apellido")
success = json.UpdateString("inte.ap2","segundo apellido")
success = json.UpdateString("drs.mode","140")
success = json.UpdateString("drs.ejer","ejercicio")

' Add required headers...
http.SetRequestHeader "eus-bizkaia-n3-version","1.0"
http.SetRequestHeader "eus-bizkaia-n3-content-type","application/xml"
http.SetRequestHeader "eus-bizkaia-n3-data",json.Emit()

url = "https://pruesarrerak.bizkaia.eus/N3B4000M/aurkezpena"
set resp = CreateObject("Chilkat.HttpResponse")
http.UncommonOptions = "SendGzipped"
success = http.HttpSb("POST",url,sbXml,"utf-8","application/octet-stream",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

http.ClearHeaders 

outFile.WriteLine("response status code: " & resp.StatusCode)

' Examine the response (it is already decompressed)
outFile.WriteLine("response body:")
outFile.WriteLine(resp.BodyStr)

outFile.Close