VBScript
VBScript
Swift Alliance LAU XML Signature
See more XML Digital Signatures Examples
Calculating the LAU for Swift Alliance File Act XML using HMAC SHA256. (The XML signature, also referred to as Local Authentication (LAU), is computed using the algorithm HMAC based on SHA-256.)Chilkat VBScript Downloads
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)
success = 0
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' We begin with the following XML:
' <?xml version="1.0" encoding="UTF-8"?>
' <Saa:DataPDU xmlns:Saa="urn:swift:saa:xsd:saa.2.0" xmlns:Sw="urn:swift:snl:ns.Sw" xmlns:SwInt="urn:swift:snl:ns.SwInt" xmlns:SwGbl="urn:swift:snl:ns.SwGbl" xmlns:SwSec="urn:swift:snl:ns.SwSec">
' <Saa:Revision>2.0.6</Saa:Revision>
' <Saa:Header>
' <Saa:Message>
' <Saa:SenderReference>Ref760FA1234</Saa:SenderReference>
' <Saa:MessageIdentifier>tsrv.fin.mt7xx.gteesstandbys</Saa:MessageIdentifier>
' <Saa:Format>File</Saa:Format>
' <Saa:SubFormat>Input</Saa:SubFormat>
' <Saa:Sender>
' <Saa:DN>cn=su8,o=ptsqgbbb,o=swift</Saa:DN>
' <Saa:FullName>
' <Saa:X1>PTSQGBBBXXX</Saa:X1>
' </Saa:FullName>
' </Saa:Sender>
' <Saa:Receiver>
' <Saa:DN>cn=abc,ou=saa,o=xxx,o=swift</Saa:DN>
' <Saa:FullName>
' <Saa:X1>PTSXXXXXXXX</Saa:X1>
' <Saa:X2>saa</Saa:X2>
' </Saa:FullName>
' </Saa:Receiver>
' <Saa:InterfaceInfo>
' <Saa:UserReference>CRE...</Saa:UserReference>
' <Saa:MessageCreator>ApplicationInterface</Saa:MessageCreator>
' <Saa:MessageContext>Original</Saa:MessageContext>
' <Saa:MessageNature>Financial</Saa:MessageNature>
' </Saa:InterfaceInfo>
' <Saa:NetworkInfo>
' <Saa:Priority>Normal</Saa:Priority>
' <Saa:IsPossibleDuplicate>true</Saa:IsPossibleDuplicate>
' <Saa:Service>swift.corp.fast!x</Saa:Service>
' <Saa:Network>Application</Saa:Network>
' <Saa:SessionNr>0080</Saa:SessionNr>
' <Saa:SeqNr>000001</Saa:SeqNr>
' <Saa:SWIFTNetNetworkInfo>
' <Saa:RequestType>tsrv.fin.mt7xx.gteesstandbys</Saa:RequestType>
' <Saa:Reference>2f949999-d32e-49eb-9999-9a819b9b9c0d</Saa:Reference>
' <Saa:FileInfo>SwCompression=Zip</Saa:FileInfo>
' </Saa:SWIFTNetNetworkInfo>
' </Saa:NetworkInfo>
' <Saa:SecurityInfo>
' <Saa:SWIFTNetSecurityInfo>
' <Saa:FileDigestAlgorithm>SHA-256</Saa:FileDigestAlgorithm>
' <Saa:FileDigestValue>9tnnjIgsowPSU+ehm8Rb0J5TvZIvhCYnySzFkpur1aw=</Saa:FileDigestValue>
' </Saa:SWIFTNetSecurityInfo>
' </Saa:SecurityInfo>
' <Saa:FileLogicalName>Payload.ZIP</Saa:FileLogicalName>
' <Saa:ExpiryDateTime>20210712074808</Saa:ExpiryDateTime>
' </Saa:Message>
' </Saa:Header>
' <Saa:Body>Payload.ZIP</Saa:Body>
' </Saa:DataPDU>
' Load the XML file to be signed.
set sbXml = CreateObject("Chilkat.StringBuilder")
success = sbXml.LoadFile("c:/someDir/fileToSign.xml","utf-8")
If (success = 0) Then
outFile.WriteLine("Failed to load XML file.")
WScript.Quit
End If
' We need to add a "LAU" XML element just before the "</Saa:DataPDU>"
numReplaced = sbXml.Replace("</Saa:DataPDU>","<LAU xmlns=""urn:swift:saa:xsd:saa.2.0""></LAU></Saa:DataPDU>")
set gen = CreateObject("Chilkat.XmlDSigGen")
gen.SigLocation = "Saa:DataPDU|LAU"
gen.SigLocationMod = 0
gen.SigNamespacePrefix = "ds"
gen.SigNamespaceUri = "http://www.w3.org/2000/09/xmldsig#"
gen.SignedInfoCanonAlg = "EXCL_C14N"
gen.SignedInfoDigestMethod = "sha256"
gen.Behaviors = "CompactSignedXml"
' Sign the entire document.
success = gen.AddSameDocRef("","sha256","EXCL_C14N","","")
' Set our HMAC key
success = gen.SetHmacKey("Abcdef0123456789Abcdef0123456789","ascii")
' Sign the XML:
success = gen.CreateXmlDSigSb(sbXml)
If (success = 0) Then
outFile.WriteLine(gen.LastErrorText)
WScript.Quit
End If
' Examine the signed XML
outFile.WriteLine(sbXml.GetAsString())
' Save the signed XML to a file.
success = sbXml.WriteFile("c:/someDir/signedFile.xml","utf-8",0)
outFile.Close