(VBScript) StringBuilder GetBefore

Demonstrates the StringBuilder.GetBefore method.

The GetBefore method was added in Chilkat v9.5.0.77

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append("www.chilkatsoft.com")

' The GetBefore method returns the contents of the string up to but not including
' the marker string.  If the remove flag is 1, then both the returned string AND
' the marker are removed.
removeFlag = 0
marker = "."
substr = sb.GetBefore(marker,removeFlag)
outFile.WriteLine("substr = " & substr)
outFile.WriteLine("sb contains: " & sb.GetAsString())

' Output:
' substr = www
' sb contains: www.chilkatsoft.com

removeFlag = 1
substr = sb.GetBefore(marker,removeFlag)
outFile.WriteLine("substr = " & substr)
outFile.WriteLine("sb contains: " & sb.GetAsString())

' Output:
' substr = www
' sb contains: chilkatsoft.com

' If the marker is not found, and the removeFlag is 1,
' then the entire string is returned and the sb is cleared.
' For example:
sb.Clear 
success = sb.Append("111--222--333--444")
marker = "--"
removeFlag = 1
Do While (sb.Length > 0)
    substr = sb.GetBefore(marker,removeFlag)
    outFile.WriteLine("substr = " & substr & ", sb contains: " & sb.GetAsString())
Loop

' Output is:
' substr = 111, sb contains: 222--333--444
' substr = 222, sb contains: 333--444
' substr = 333, sb contains: 444
' substr = 444, sb contains: 

outFile.Close