VBScript
Generate RSA SSH Key

Generates an RSA SSH key and saves to various public and private key file formats (OpenSSH and PuTTY).
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set key = CreateObject("Chilkat.SshKey")

' numBits may range from 384 to 4096.  Typical values are
' 1024 or 2048.  (must be a multiple of 64)
' A good choice for the exponent is 65537.  Chilkat recommends
' always using this value.
numBits = 2048
exponent = 65537
success = key.GenerateRsaKey(numBits,exponent)
If (success <> 1) Then
    outFile.WriteLine("Bad params passed to RSA key generation method.")
    WScript.Quit
End If

' Note: Generating a public/private key pair is CPU intensive
' and may take a short amount of time (more than few seconds,
' but less than a minute).

' Export the RSA private key to OpenSSH, PuTTY, and XML and save. 
exportEncrypted = 0
exportedKey = key.ToOpenSshPrivateKey(exportEncrypted)
' Chilkat provides a SaveText method for convenience...
success = key.SaveText(exportedKey,"privkey_openssh_unencrypted.pem")

' Export with encryption to OpenSSH private key format:
key.Password = "secret"
exportEncrypted = 1
exportedKey = key.ToOpenSshPrivateKey(exportEncrypted)
success = key.SaveText(exportedKey,"privkey_openssh_encrypted.pem")

' Export the RSA private key to unencrypted PuTTY format:
exportEncrypted = 0
exportedKey = key.ToPuttyPrivateKey(exportEncrypted)
success = key.SaveText(exportedKey,"privkey_putty_unencrypted.ppk")

' Export the RSA private key to encrypted PuTTY format:
key.Password = "secret"
exportEncrypted = 1
exportedKey = key.ToPuttyPrivateKey(exportEncrypted)
success = key.SaveText(exportedKey,"privkey_putty_encrypted.ppk")

' Export private key to XML:
exportedKey = key.ToXml()
success = key.SaveText(exportedKey,"privkey.xml")

' ----------------------------------------------------
' Now for the public key....
' ----------------------------------------------------

' The Secure Shell (SSH) Public Key File Format
' is documented in RFC 4716.
exportedKey = key.ToRfc4716PublicKey()
success = key.SaveText(exportedKey,"pubkey_rfc4716.pub")

' OpenSSH has a separate public-key file format, which 
' is also supported by Chilkat SshKey:
exportedKey = key.ToOpenSshPublicKey()
success = key.SaveText(exportedKey,"pubkey_openSsh.pub")

outFile.WriteLine("Finished.")

outFile.Close