VBScript

SSH Keyboard Authentication

See more SSH Examples

Demonstrates how to implement keyboard authentication with an SSH server. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ssh = CreateObject("Chilkat.Ssh")

' Set some timeouts, in milliseconds:
ssh.ConnectTimeoutMs = 5000
ssh.IdleTimeoutMs = 15000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = ssh.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Begin keyboard authentication..
xmlResponse = ssh.StartKeyboardAuth("myLogin")
If (ssh.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' If a user authentication banner was received, then your app
' may display it prior to prompting for the password.
outFile.WriteLine("UserAuthBanner: " & ssh.UserAuthBanner)

set xml = CreateObject("Chilkat.Xml")

success = xml.LoadXml(xmlResponse)
' Assume LoadXml succeeds for the example..
If (xml.HasChildWithTag("success") = 1) Then
    outFile.WriteLine("No password required, already authenticated.")
    WScript.Quit
End If

If (xml.HasChildWithTag("error") = 1) Then
    outFile.WriteLine("Authentication already failed.")
    WScript.Quit
End If

' See the online reference documentation for Chilkat SSH.
' The XML returned by StartKeyboardAuth will contain an infoRequest
' with one or more prompts that your application may choose to display.

' Call ContinueKeyboardAuth, passing in the whatever information is requires (such as the password).
' Typically, keyboard authentication requires one call to ContinueKeyboardAuth 
' using the password.  Theoretically, the SSH server could prompt for additional pieces
' of information.  The authentication is completed when the XML returned contains
' either a "success" or "error" child node.

' This example asumes only one call to ContinueKeyboardAuth is required.
xmlResponse = ssh.ContinueKeyboardAuth("myPassword")
If (ssh.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

success = xml.LoadXml(xmlResponse)
' Assume LoadXml succeeds for the example..
If (xml.HasChildWithTag("success") = 1) Then
    outFile.WriteLine("SSH Keyboard Authentication Successful!")
    WScript.Quit
End If

If (xml.HasChildWithTag("error") = 1) Then
    outFile.WriteLine("Authentication failed.")
    WScript.Quit
End If


outFile.Close