VBScript

SSH Execute Remote Commands

Demonstrates running several commands on an SSH server using QuickCommand, which performs the entire open-channel, exec, receive, and retrieve sequence in a single call and returns the command's stdout.

Background: QuickCommand is the simplest way to run one-off commands: each call uses its own session channel on the same authenticated connection, so several commands can be issued in sequence without managing channels yourself. Because no PTY is involved the output is clean, with no prompt or echoed input to strip. Reach for the individual channel methods only when you need stderr separately, the exit status, or a long-lived interactive session.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Demonstrates running several commands on an SSH server using QuickCommand, which handles the
'  whole open-channel, exec, receive, and retrieve sequence in a single call.

set ssh = CreateObject("Chilkat.Ssh")

port = 22
success = ssh.Connect("ssh.example.com",port)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

'  Each QuickCommand call runs one command on its own session channel and returns its stdout.
strOutput = ssh.QuickCommand("df","utf-8")
If (ssh.LastMethodSuccess = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("---- df ----")
outFile.WriteLine(strOutput)

strOutput = ssh.QuickCommand("echo hello world","utf-8")
If (ssh.LastMethodSuccess = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("---- echo hello world ----")
outFile.WriteLine(strOutput)

strOutput = ssh.QuickCommand("date","utf-8")
If (ssh.LastMethodSuccess = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("---- date ----")
outFile.WriteLine(strOutput)

ssh.Disconnect 

outFile.Close