VBScript

SSH Commands to Cisco Switch

See more SSH Examples

Demonstrates how to establish an SSH session with a Cisco switch (or something similar) and send commands in a device console session. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ssh = CreateObject("Chilkat.Ssh")

success = ssh.Connect("172.16.16.100",22)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Start a shell session.
channelNum = ssh.QuickShell()
If (channelNum < 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' If the CISCO switch returns a prompt with "#", then read until we get the prompt.
' (It's not actually required that we do this, but it helps to know that all is OK at this point..)
success = ssh.ChannelReceiveUntilMatch(channelNum,"#","utf-8",1)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Show what we received so far:
outFile.WriteLine(ssh.GetReceivedText(channelNum,"utf-8"))

' Send a "show clock" command.
success = ssh.ChannelSendString(channelNum,"show clock" & vbLf,"utf-8")

' Read the output to the next interactive prompt.
success = ssh.ChannelReceiveUntilMatch(channelNum,"#","utf-8",1)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(ssh.GetReceivedText(channelNum,"utf-8"))

' Send another command and get the output, and so on...
success = ssh.ChannelSendString(channelNum,"some other command" & vbLf,"utf-8")
success = ssh.ChannelReceiveUntilMatch(channelNum,"#","utf-8",1)
If (success <> 1) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(ssh.GetReceivedText(channelNum,"utf-8"))

ssh.Disconnect 

outFile.Close