VBScript

SSH Auth Failure Reason (AuthenticatePwPk)

See more SSH Examples

This example demonstrates how to determine the failure reason for the case where both a password and private key are required for authentication. If authentication fails, was it because of an invalid private key, or an invalid password? VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load a private key to be used for SSH authentication.
set key = CreateObject("Chilkat.SshKey")
key.Password = "key_password"

success = key.FromOpenSshPrivateKey(key.LoadText("qa_data/my_private_key_file"))
If (success = 0) Then
    outFile.WriteLine(key.LastErrorText)
    WScript.Quit
End If

set ssh = CreateObject("Chilkat.Ssh")

success = ssh.Connect("ssh.example.com",22)
If (success = 0) Then
    outFile.WriteLine(ssh.LastErrorText)
    WScript.Quit
End If

' Authenticate using both a password and private key.
success = ssh.AuthenticatePwPk("myLogin","myPassword",key)
If (success = 1) Then
    outFile.WriteLine("Authentication is successful!")
    WScript.Quit
End If

' If we get here, it means the authentication failed.
' Examine the last JSON data to get information..

set json = CreateObject("Chilkat.JsonObject")
ssh.GetLastJsonData json

json.EmitCompact = 0

' This is the JSON if the key is correct, but the password is incorrect:

' {
'   "public_key_type": "rsa",
'   "partialAuthResult": "publickey success. continue to authenticate with password...",
'   "authResult": "failed",
'   "authFailReason": "Password is incorrect"
' }

' This is the JSON if the key is incorrect.  We won't know if the password is also incorrect until
' the key is made correct so that authentication proceeds to check the password.

' {
'   "public_key_type": "rsa",
'   "authResult": "failed",
'   "authFailReason": "Key is incorrect"
' }

' To get the authResult anbd authFailReason:
outFile.WriteLine("authResult: " & json.StringOf("authResult"))
outFile.WriteLine("authFailReason: " & json.StringOf("authFailReason"))

outFile.Close