(VBScript) SQS Send Message

Note: This example requires a patch to work properly. It requires Chilkat v9.5.0.61, which can be obtained upon request to support@chilkatsoft.com

Delivers a message to the specified queue. With Amazon SQS, you now have the ability to send large payload messages that are up to 256KB (262,144 bytes) in size.

See SQS SendMessage or detailed information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: This example requires a patch to work properly.  
' It requires Chilkat v9.5.0.61, which can be obtained upon request to support@chilkatsoft.com

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","SendMessage")
success = rest.AddQueryParam("MessageBody","This is the message body which can be up to 256K in size.")
success = rest.AddQueryParam("MessageAttribute.1.Name","test_attribute_name_1")
success = rest.AddQueryParam("MessageAttribute.1.Value.StringValue","test_attribute_value_1")
success = rest.AddQueryParam("MessageAttribute.1.Value.DataType","String")
success = rest.AddQueryParam("MessageAttribute.2.Name","test_attribute_name_2")
success = rest.AddQueryParam("MessageAttribute.2.Value.StringValue","test_attribute_value_2")
success = rest.AddQueryParam("MessageAttribute.2.Value.DataType","String")

' Use the actual path part of your SQS queue URL here:
responseXml = rest.FullRequestFormUrlEncoded("POST","/123456789123/chilkatTest")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("request header = " & rest.LastRequestHeader)
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    success = xml.LoadXml(responseXml)
    outFile.WriteLine(xml.GetXml())
    WScript.Quit
End If

' Examine the successful XML response.
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())
outFile.WriteLine("----")

' A successful response looks like this:
' <?xml version="1.0" encoding="utf-8" ?>
' <SendMessageResponse>
'     <SendMessageResult>
'         <MD5OfMessageBody>
'             fafb00f5732ab283681e124bf8747ed1
'         </MD5OfMessageBody>
'         <MD5OfMessageAttributes>
' 	    3ae8f24a165a8cedc005670c81a27295
'         </MD5OfMessageAttributes>
'         <MessageId>
'             5fea7756-0ea4-451a-a703-a558b933e274
'         </MessageId>
'     </SendMessageResult>
'     <ResponseMetadata>
'         <RequestId>
'             27daac76-34dd-47df-bd01-1f6e873584a0
'         </RequestId>
'     </ResponseMetadata>
' </SendMessageResponse>

' Get some values from the response XML:
outFile.WriteLine("Body: " & xml.ChilkatPath("SendMessageResult|MD5OfMessageBody|*"))
outFile.WriteLine("MessageId: " & xml.ChilkatPath("SendMessageResult|MessageId|*"))
outFile.WriteLine("RequestId: " & xml.ChilkatPath("ResponseMetadata|RequestId|*"))

outFile.Close