VBScript

SQS Purge Queue

See more Amazon SQS Examples

Deletes all the messages in an SQS queue.

See SQS PurgeQueue or detailed information.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","PurgeQueue")

' Use the actual path part of your SQS queue URL here:
responseXml = rest.FullRequestNoBody("GET","/123456789123/chilkatTest")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    WScript.Quit
End If

' Examine the successful XML response.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())

' A sample PurgeQueue response:
' <PurgeQueueResponse>
'     <ResponseMetadata>
'         <RequestId>
'             6fde8d1e-52cd-4581-8cd9-c512f4c64223
'         </RequestId>
'     </ResponseMetadata>
' </PurgeQueueResponse>

outFile.Close