(VBScript) SQS Create Queue

Creates a new SQS queue.

See SQS CreateQueue or detailed information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","CreateQueue")
success = rest.AddQueryParam("QueueName","testQueue")
success = rest.AddQueryParam("Attribute.1.Name","VisibilityTimeout")
success = rest.AddQueryParam("Attribute.1.Value","40")

responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    WScript.Quit
End If

' Examine the successful XML response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())

' A sample CreateQueue response:
' <CreateQueueResponse>
'     <CreateQueueResult>
'         <QueueUrl>
'             http://queue.amazonaws.com/123456789012/testQueue
'         </QueueUrl>
'     </CreateQueueResult>
'     <ResponseMetadata>
'         <RequestId>
'             7a62c49f-347e-4fc4-9331-6e8e7a96aa73
'         </RequestId>
'     </ResponseMetadata>
' </CreateQueueResponse>

outFile.Close