VBScript Requires Chilkat v11.0.0+

Get SpamAssassin Score for an Email

Uses Postmark’s spam API (a RESTfull interface to the SpamAssassin filter tool) to analyze an email to get a spam score.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  First build an email to check.
set email = CreateObject("Chilkat.Email")
email.Subject = "this is a test"
email.From = "support@chilkatsoft.com"
success = email.AddTo("John Doe","john@example.com")
success = email.AddPlainTextAlternativeBody("this is a test")
success = email.AddHtmlAlternativeBody("<html><body><b>Hello John!</b><p>This is a test</p></body></html>")
success = email.AddFileAttachment2("qa_data/jpg/starfish.jpg","image/jpeg")

'  Check this email by implementing this curl command:

'  curl -X POST "https://spamcheck.postmarkapp.com/filter"
'  -H "Accept: application/json"
'  -H "Content-Type: application/json"
'  -v
'  -d '{"email":"raw dump of email", "options":"short"}'

set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("email",email.GetMime())
success = json.UpdateString("options","short")

set http = CreateObject("Chilkat.Http")
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://spamcheck.postmarkapp.com/filter",json,"application/json",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status code = " & resp.StatusCode)
outFile.WriteLine("response body: ")
outFile.WriteLine(resp.BodyStr)

outFile.Close