VBScript
Amazon SP-API Upload Feed

Upload a feed document to the feed previously created.
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load your own feed data file.
set sbRequestBody = CreateObject("Chilkat.StringBuilder")
success = sbRequestBody.LoadFile("C:/AAWorkarea/test-despatch-upload.txt","utf-8")
If (success = 0) Then
    outFile.WriteLine("Failed to load test-despatch-upload.txt.")
    WScript.Quit
End If

' The SP-API Create Feed example returned JSON such as this.

' {
'   "feedDocumentId": "amzn1.tortuga.4.eu.8fb6f9c4-XXXX-4e7f-824f-XXXXXXXXXXXXX.ZZZZZZZZZZZZZZ",
'   "url": "https://tortuga-prod-eu.s3-eu-west-1.amazonaws.com/%2FNinetyDays/amzn1.tortuga.4.eu.8fb6f9c4-XXXX-4e7f-824f-XXXXXXXXXXXXX.ZZZZZZZZZZZZZZ?X-Amz-Algorithm=AWS4-HMAC-SHA256&X-Amz-Date=20230222T014944Z&X-Amz-SignedHeaders=content-type%3Bhost&X-Amz-Expires=300&X-Amz-Credential=XXXXXXXXXXXXXXXXX%2F20230222%2Feu-west-1%2Fs3%2Faws4_request&X-Amz-Signature=XXXXXXXXXXXXXXXXXXXXXXXXXXXX"
' }

' Load the JSON feed file created by this example:  SP-API Create Feed
set jsonFeedInfo = CreateObject("Chilkat.JsonObject")
success = jsonFeedInfo.LoadFile("qa_data/json/sp_api_feed_upload_info.json")
If (success = 0) Then
    outFile.WriteLine(jsonFeedInfo.LastErrorText)
    WScript.Quit
End If

' Get the pre-signed URL
url = jsonFeedInfo.StringOf("url")

' We can use the Chilkat HTTP object because the URL is pre-signed.
' We don't need to add our own AWS authentication because it's already in the pre-signed URL,
' which is only valid for short amount of time.
set http = CreateObject("Chilkat.Http")

' NOTE: The string "text/tab-separated-values; charset=UTF-8" must match exactly the contentType specified when creating the feed.
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSb("PUT",url,sbRequestBody,"utf-8","text/tab-separated-values; charset=UTF-8",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("status code = " & resp.StatusCode)
outFile.WriteLine("status text = " & resp.StatusText)
outFile.WriteLine("response body:")
outFile.WriteLine(resp.BodyStr)

outFile.Close