VBScript

Amazon SP-API Sellers Get Marketplace Participations

See more Amazon SP-API Examples

Demonstrates Amazon SP-API Sellers API -- get marketplace participations. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "execute-api"
' Use the region that is correct for your needs.
authAws.Region = "eu-west-1"

set rest = CreateObject("Chilkat.Rest")
bTls = 1
port = 443
bAutoReconnect = 1
' Make sure to use the correct domain.
' In this example, we are using "sandbox.sellingpartnerapi-eu.amazon.com"
success = rest.Connect("sandbox.sellingpartnerapi-eu.amazon.com",port,bTls,bAutoReconnect)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.SetAuthAws(authAws)

' Load the previously obtained LWA access token.
' See Fetch SP-API LWA Access Token
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/sp_api_lwa_token.json")
If (success = 0) Then
    outFile.WriteLine("Failed to load LWA access token.")
    WScript.Quit
End If

' Add the x-amz-access-token request header.
lwa_token = jsonToken.StringOf("access_token")
success = rest.ClearAllHeaders()
success = rest.AddHeader("x-amz-access-token",lwa_token)

set sbResponse = CreateObject("Chilkat.StringBuilder")
uri = "/sellers/v1/marketplaceParticipations"
success = rest.FullRequestNoBodySb("GET",uri,sbResponse)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Examine the response status.
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    outFile.WriteLine("Response status text: " & rest.ResponseStatusText)
    outFile.WriteLine("Response body: ")
    outFile.WriteLine(sbResponse.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine(sbResponse.GetAsString())

' If successful, gets a JSON response such as the following:

' {
'   "payload": [
'     {
'       "marketplace": {
'         "id": "ATVPDKIKX0DER",
'         "countryCode": "US",
'         "name": "Amazon.com",
'         "defaultCurrencyCode": "USD",
'         "defaultLanguageCode": "en_US",
'         "domainName": "www.amazon.com"
'       },
'       "participation": {
'         "isParticipating": true,
'         "hasSuspendedListings": false
'       }
'     }
'   ]
' }

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

set json = CreateObject("Chilkat.JsonObject")

success = json.LoadSb(sbResponse)

i = 0
count_i = json.SizeOfArray("payload")
Do While i < count_i
    json.I = i
    Id = json.StringOf("payload[i].marketplace.id")
    CountryCode = json.StringOf("payload[i].marketplace.countryCode")
    Name = json.StringOf("payload[i].marketplace.name")
    DefaultCurrencyCode = json.StringOf("payload[i].marketplace.defaultCurrencyCode")
    DefaultLanguageCode = json.StringOf("payload[i].marketplace.defaultLanguageCode")
    DomainName = json.StringOf("payload[i].marketplace.domainName")
    IsParticipating = json.BoolOf("payload[i].participation.isParticipating")
    HasSuspendedListings = json.BoolOf("payload[i].participation.hasSuspendedListings")
    i = i + 1
Loop

outFile.WriteLine("Success!")

outFile.Close