(VBScript) Amazon SP-API Get Specific Order

See more Amazon SP-API Examples

Get a specific Amazon Seller order.

For more information, see https://developer-docs.amazon.com/sp-api/docs/orders-api-v0-reference#getorders

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Gets information for this order ID
' The order ID is something like "902-1845936-5435065" and it is the AmazonOrderId returned in the JSON when getting the list of orders.  For example:
' {
'   "payload": {
'     "CreatedBefore": "1.569521782042E9",
'     "Orders": [
'       {
'         "AmazonOrderId": "902-1845936-5435065",
'         "PurchaseDate": "1970-01-19T03:58:30Z",
' ...

' However, when using the sandbox, instead use the explicit keyword TEST_CASE_200
orderId = "TEST_CASE_200"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "execute-api"
' Use the region that is correct for your needs.
authAws.Region = "eu-west-1"

' First get a restricted data token for the given order ID.
' This requires an LWA access token which cannot be more than 1 hour old.
' See Fetch SP-API LWA Access Token
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonLwaToken = CreateObject("Chilkat.JsonObject")
success = jsonLwaToken.LoadFile("qa_data/tokens/sp_api_lwa_token.json")
If (success = 0) Then
    outFile.WriteLine("Failed to load LWA access token.")
    WScript.Quit
End If

' Must use the non-sandbox domain for getting the RDT.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
success = rest.Connect("sellingpartnerapi-eu.amazon.com",443,1,1)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.SetAuthAws(authAws)

' Add the x-amz-access-token request header.
lwa_token = jsonLwaToken.StringOf("access_token")
success = rest.ClearAllHeaders()
success = rest.AddHeader("x-amz-access-token",lwa_token)

' We're going to send a POST with the following JSON body:

' {
'   "restrictedResources": [
'     {
'       "method": "GET",
'       "path": "/orders/v0/orders/{orderId}",
'       "dataElements": ["buyerInfo", "shippingAddress"]
'     }
'   ]
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/orders/v0/orders/")
success = sbPath.Append(orderId)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonRc = CreateObject("Chilkat.JsonObject")
success = jsonRc.UpdateString("restrictedResources[0].method","GET")
success = jsonRc.UpdateString("restrictedResources[0].path",sbPath.GetAsString())
success = jsonRc.UpdateString("restrictedResources[0].dataElements[0]","buyerInfo")
success = jsonRc.UpdateString("restrictedResources[0].dataElements[1]","shippingAddress")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRequest = CreateObject("Chilkat.StringBuilder")
success = jsonRc.EmitSb(sbRequest)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponse = CreateObject("Chilkat.StringBuilder")
uri = "/tokens/2021-03-01/restrictedDataToken"
success = rest.FullRequestSb("POST",uri,sbRequest,sbResponse)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Examine the response status.
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    outFile.WriteLine("Response status code: " & statusCode)
    outFile.WriteLine("Response status text: " & rest.ResponseStatusText)
    outFile.WriteLine("Response body: ")
    outFile.WriteLine(sbResponse.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Get the restricted data token.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResp = CreateObject("Chilkat.JsonObject")
success = jsonResp.LoadSb(sbResponse)
restrictedDataToken = jsonResp.StringOf("restrictedDataToken")
outFile.WriteLine("Restricted Data Token: " & restrictedDataToken)

' ------------------------------------------------------------------------------------------------------------
' ------------------------------------------------------------------------------------------------------------
' Now that we have the RDT, we can use it to get information about the order.
' 
' Yes, the SP-API is horribly tedious and painful.  You must use an RDT specifically tailored to each request requiring an RDT,
' the RDT must not be over an hour old, and if you need to get a new RDT you must get it using an LWA token that itself is not
' more than an hour old.  If the LWA is more than an hour old, you must get a new one.  Ughhh!!!!!
' ------------------------------------------------------------------------------------------------------------

' Disconnect from the non-sandbox domain.  This example will use the sandbox.
' (The RDT was obtained using the non-sandbox domain.  For some reason, the sandbox domain does not work for getting the RDT.)
success = rest.Disconnect(100)

success = rest.Connect("sandbox.sellingpartnerapi-eu.amazon.com",443,1,1)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.SetAuthAws(authAws)

success = rest.ClearAllHeaders()
success = rest.AddHeader("x-amz-access-token",restrictedDataToken)

success = rest.ClearAllQueryParams()
success = rest.AddQueryParam("MarketplaceIds","ATVPDKIKX0DER")

success = rest.ClearAllPathParams()
success = rest.AddPathParam("{orderId}",orderId)

uri = "/orders/v0/orders/{orderId}"
success = rest.FullRequestNoBodySb("GET",uri,sbResponse)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Examine the response status.
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    outFile.WriteLine("Response status text: " & rest.ResponseStatusText)
    outFile.WriteLine("Response body: ")
    outFile.WriteLine(sbResponse.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine(sbResponse.GetAsString())

' If successful, gets a JSON response such as the following:

' {
'   "payload": {
'     "AmazonOrderId": "902-1845936-5435065",
'     "PurchaseDate": "1970-01-19T03:58:30Z",
'     "LastUpdateDate": "1970-01-19T03:58:32Z",
'     "OrderStatus": "Unshipped",
'     "FulfillmentChannel": "MFN",
'     "SalesChannel": "Amazon.com",
'     "ShipServiceLevel": "Std US D2D Dom",
'     "OrderTotal": {
'       "CurrencyCode": "USD",
'       "Amount": "11.01"
'     },
'     "NumberOfItemsShipped": 0,
'     "NumberOfItemsUnshipped": 1,
'     "PaymentMethod": "Other",
'     "PaymentMethodDetails": [
'       "Standard"
'     ],
'     "IsReplacementOrder": false,
'     "MarketplaceId": "ATVPDKIKX0DER",
'     "ShipmentServiceLevelCategory": "Standard",
'     "OrderType": "StandardOrder",
'     "EarliestShipDate": "1970-01-19T03:59:27Z",
'     "LatestShipDate": "1970-01-19T04:05:13Z",
'     "EarliestDeliveryDate": "1970-01-19T04:06:39Z",
'     "LatestDeliveryDate": "1970-01-19T04:15:17Z",
'     "IsBusinessOrder": false,
'     "IsPrime": false,
'     "IsGlobalExpressEnabled": false,
'     "IsPremiumOrder": false,
'     "IsSoldByAB": false,
'     "IsIBA": false,
'     "DefaultShipFromLocationAddress": {
'       "Name": "MFNIntegrationTestMerchant",
'       "AddressLine1": "2201 WESTLAKE AVE",
'       "City": "SEATTLE",
'       "StateOrRegion": "WA",
'       "PostalCode": "98121-2778",
'       "CountryCode": "US",
'       "Phone": "+1 480-386-0930 ext. 73824",
'       "AddressType": "Commercial"
'     },
'     "FulfillmentInstruction": {
'       "FulfillmentSupplySourceId": "sampleSupplySourceId"
'     },
'     "IsISPU": false,
'     "IsAccessPointOrder": false,
'     "AutomatedShippingSettings": {
'       "HasAutomatedShippingSettings": false
'     },
'     "EasyShipShipmentStatus": "PendingPickUp",
'     "ElectronicInvoiceStatus": "NotRequired"
'   }
' }

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")

success = json.LoadSb(sbResponse)

AmazonOrderId = json.StringOf("payload.AmazonOrderId")
PurchaseDate = json.StringOf("payload.PurchaseDate")
LastUpdateDate = json.StringOf("payload.LastUpdateDate")
OrderStatus = json.StringOf("payload.OrderStatus")
FulfillmentChannel = json.StringOf("payload.FulfillmentChannel")
SalesChannel = json.StringOf("payload.SalesChannel")
ShipServiceLevel = json.StringOf("payload.ShipServiceLevel")
CurrencyCode = json.StringOf("payload.OrderTotal.CurrencyCode")
Amount = json.StringOf("payload.OrderTotal.Amount")
NumberOfItemsShipped = json.IntOf("payload.NumberOfItemsShipped")
NumberOfItemsUnshipped = json.IntOf("payload.NumberOfItemsUnshipped")
PaymentMethod = json.StringOf("payload.PaymentMethod")
IsReplacementOrder = json.BoolOf("payload.IsReplacementOrder")
MarketplaceId = json.StringOf("payload.MarketplaceId")
ShipmentServiceLevelCategory = json.StringOf("payload.ShipmentServiceLevelCategory")
OrderType = json.StringOf("payload.OrderType")
EarliestShipDate = json.StringOf("payload.EarliestShipDate")
LatestShipDate = json.StringOf("payload.LatestShipDate")
EarliestDeliveryDate = json.StringOf("payload.EarliestDeliveryDate")
LatestDeliveryDate = json.StringOf("payload.LatestDeliveryDate")
IsBusinessOrder = json.BoolOf("payload.IsBusinessOrder")
IsPrime = json.BoolOf("payload.IsPrime")
IsGlobalExpressEnabled = json.BoolOf("payload.IsGlobalExpressEnabled")
IsPremiumOrder = json.BoolOf("payload.IsPremiumOrder")
IsSoldByAB = json.BoolOf("payload.IsSoldByAB")
IsIBA = json.BoolOf("payload.IsIBA")
Name = json.StringOf("payload.DefaultShipFromLocationAddress.Name")
AddressLine1 = json.StringOf("payload.DefaultShipFromLocationAddress.AddressLine1")
City = json.StringOf("payload.DefaultShipFromLocationAddress.City")
StateOrRegion = json.StringOf("payload.DefaultShipFromLocationAddress.StateOrRegion")
PostalCode = json.StringOf("payload.DefaultShipFromLocationAddress.PostalCode")
CountryCode = json.StringOf("payload.DefaultShipFromLocationAddress.CountryCode")
Phone = json.StringOf("payload.DefaultShipFromLocationAddress.Phone")
AddressType = json.StringOf("payload.DefaultShipFromLocationAddress.AddressType")
FulfillmentSupplySourceId = json.StringOf("payload.FulfillmentInstruction.FulfillmentSupplySourceId")
IsISPU = json.BoolOf("payload.IsISPU")
IsAccessPointOrder = json.BoolOf("payload.IsAccessPointOrder")
HasAutomatedShippingSettings = json.BoolOf("payload.AutomatedShippingSettings.HasAutomatedShippingSettings")
EasyShipShipmentStatus = json.StringOf("payload.EasyShipShipmentStatus")
ElectronicInvoiceStatus = json.StringOf("payload.ElectronicInvoiceStatus")
i = 0
count_i = json.SizeOfArray("payload.PaymentMethodDetails")
Do While i < count_i
    json.I = i
    strVal = json.StringOf("payload.PaymentMethodDetails[i]")
    i = i + 1
Loop

outFile.WriteLine("Success!")

outFile.Close