VBScript

Create Restricted Data Token (RDT)

See more Amazon SP-API Examples

Returns a Restricted Data Token (RDT) for one or more restricted resources that you specify. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "execute-api"
' Use the region that is correct for your needs.
authAws.Region = "eu-west-1"

set rest = CreateObject("Chilkat.Rest")
bTls = 1
port = 443
bAutoReconnect = 1
' The sandbox endpoint (sandbox.sellingpartnerapi-eu.amazon.com) fails.
' Use the production endpoint and see the note below.
success = rest.Connect("sellingpartnerapi-eu.amazon.com",port,bTls,bAutoReconnect)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.SetAuthAws(authAws)

' Load the previously obtained LWA access token.
' See Fetch SP-API LWA Access Token
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/sp_api_lwa_token.json")
If (success = 0) Then
    outFile.WriteLine("Failed to load LWA access token.")
    WScript.Quit
End If

' Add the x-amz-access-token request header.
lwa_token = jsonToken.StringOf("access_token")
success = rest.ClearAllHeaders()
success = rest.AddHeader("x-amz-access-token",lwa_token)

' We're going to send a POST with the following JSON body:

' {
'   "restrictedResources": [
'     {
'       "method": "GET",
'       "path": "/orders/v0/orders",
'       "dataElements": ["buyerInfo", "shippingAddress"]
'     }
'   ]
' }

' Use this online tool to generate code from sample JSON: 
' Generate Code to Create JSON

set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("restrictedResources[0].method","GET")
success = json.UpdateString("restrictedResources[0].path","/orders/v0/orders")
success = json.UpdateString("restrictedResources[0].dataElements[0]","buyerInfo")
success = json.UpdateString("restrictedResources[0].dataElements[1]","shippingAddress")

set sbRequest = CreateObject("Chilkat.StringBuilder")
success = json.EmitSb(sbRequest)

set sbResponse = CreateObject("Chilkat.StringBuilder")
uri = "/tokens/2021-03-01/restrictedDataToken"
success = rest.FullRequestSb("POST",uri,sbRequest,sbResponse)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ------------------------------------------------------------------------------------
' Note: Using the sandbox endpoint, such as sandbox.sellingpartnerapi-eu.amazon.com
' results in a response status code of 400 with the following error:
' [{"code":"InvalidInput","message":"Could not match input arguments"}]
' Getting a restricted data token seems to only work with the production endpoint.
' ------------------------------------------------------------------------------------

' Examine the response status.
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    outFile.WriteLine("Response status code: " & statusCode)
    outFile.WriteLine("Response status text: " & rest.ResponseStatusText)
    outFile.WriteLine("Response body: ")
    outFile.WriteLine(sbResponse.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine(sbResponse.GetAsString())

' If successful, gets a JSON response such as the following:

' {
'   "expiresIn": 3600,
'   "restrictedDataToken": "Atz.sprdt|AYAB.....TQ="
' }

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

set jsonResp = CreateObject("Chilkat.JsonObject")
success = jsonResp.LoadSb(sbResponse)

expiresIn = jsonResp.IntOf("expiresIn")
restrictedDataToken = jsonResp.StringOf("restrictedDataToken")

' Save the RDT for subsequent use..
success = jsonResp.WriteFile("qa_data/tokens/sp_api_rdt_token.json")

outFile.WriteLine("Success!")

outFile.Close