(VBScript) Socket Receive String Until Specific Byte Value is Received

Demonstrates the Chilkat Socket ReceiveStringUntilByte method.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Socket")
set sock = CreateObject("Chilkat.Socket")

' --------------------------------------------------------------------
' This example uses the public TCP echo service at https://tcpbin.com/
' --------------------------------------------------------------------

useTls = 0
port = 4242
maxWaitMs = 5000
success = sock.Connect("tcpbin.com",port,useTls,maxWaitMs)
If (success = 0) Then
    outFile.WriteLine(sock.LastErrorText)
    WScript.Quit
End If

' Wait a max of 2 seconds for a response..
sock.MaxReadIdleMs = 2000

' Send some strings, each terminated by a 0 byte.
success = sock.SendString("This is the 1st string")
success = sock.SendByte(0)
success = sock.SendString("This is string number 2")
success = sock.SendByte(0)

' The tcpbin.com echo server only echoes after receiving an LF (linefeed char)
success = sock.SendByte(10)

' Now let's receive what is echoed back....
' Receive each string and the NULL byte.
' The call to ReceiveStringUntilByte will receive incoming data until the lookForByte is encountered.
' The lookForByte is receive and discarded (it is not returned in the string)
lookForByte = 0
s1 = sock.ReceiveStringUntilByte(lookForByte)
If (sock.LastMethodSuccess = 0) Then
    outFile.WriteLine(sock.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(s1)

s2 = sock.ReceiveStringUntilByte(lookForByte)
If (sock.LastMethodSuccess = 0) Then
    outFile.WriteLine(sock.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(s2)

' The echo server will also echo back the final LF
success = sock.ReceiveByte(1)
maxWaitMs = 100
success = sock.Close(100)

' Output:
' This is the 1st string
' This is string number 2

outFile.Close