VBScript

Simple SOAP Request

See more HTTP Examples

Demonstrates how to send a simple SOAP request. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' Create the following XML to be sent in the SOAP request body.

' <soapenv:Envelope xmlns:dat="http://www.dataaccess.com/webservicesserver/" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
'     <soapenv:Header/>
'     <soapenv:Body>
'         <dat:NumberToDollars>
'             <dat:dNum>99.0</dat:dNum>
'         </dat:NumberToDollars>
'     </soapenv:Body>
' </soapenv:Envelope>

set xml = CreateObject("Chilkat.Xml")
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:dat","http://www.dataaccess.com/webservicesserver/")
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|dat:NumberToDollars|dat:dNum","99.0"

' In a SOAP HTTP request, including the XML declaration (<?xml version="1.0" encoding="UTF-8"?>) in the XML body is generally not required. 
xml.EmitXmlDecl = 0
soapRequestBody = xml.GetXml()

endpoint = "https://www.dataaccess.com/webservicesserver/numberconversion.wso"
soapAction = ""
'  For SOAP requests, the standard Content-Type is usually set to "text/xml" or "application/soap+xml"
contentType = "text/xml"

set http = CreateObject("Chilkat.Http")

http.ClearHeaders 
http.SetRequestHeader "SOAPAction",soapAction

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpStr("POST",endpoint,soapRequestBody,"utf-8",contentType,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Get the XML response body.
set responseXml = CreateObject("Chilkat.Xml")
success = resp.GetBodyXml(responseXml)

statusCode = resp.StatusCode
outFile.WriteLine("response status code: " & statusCode)

' If the status code does not indicate succcess, then show the response XML,
' which probably contains error information.
If (statusCode <> 200) Then
    outFile.WriteLine(responseXml.GetXml())
    WScript.Quit
End If

outFile.WriteLine(responseXml.GetXml())

' Parse the successful SOAP response XML.

' This is a sample of the response XML, but the namespace prefixes will be different.
' We can parse the result using "*" for the namespace prefixes (see below).

' <soapenv:Envelope xmlns:dat="http://www.dataaccess.com/webservicesserver/" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
'     <soapenv:Header/>
'     <soapenv:Body>
'         <dat:NumberToDollarsResponse>
'             <dat:NumberToDollarsResult>string</dat:NumberToDollarsResult>
'         </dat:NumberToDollarsResponse>
'     </soapenv:Body>
' </soapenv:Envelope>

dat_NumberToDollarsResult = responseXml.GetChildContent("*:Body|*:NumberToDollarsResponse|*:NumberToDollarsResult")
outFile.WriteLine("result: " & dat_NumberToDollarsResult)

outFile.Close