(VBScript) SNS Subscribe Email Address

Subscribe an email address to an SNS topic.

See SNS Subscribe for more information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sns.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sns.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sns"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","Subscribe")
success = rest.AddQueryParam("Endpoint","somebody@some-email-address.com")
success = rest.AddQueryParam("Protocol","email")
success = rest.AddQueryParam("TopicArn","arn:aws:sns:us-west-2:957491831129:chilkat")

responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    WScript.Quit
End If

' Examine the successful XML response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())

' To get the SubscriptionArn (which in this case is "pending confirmation")
outFile.WriteLine("SubscriptionArn: " & xml.ChilkatPath("SubscribeResult|SubscriptionArn|*"))

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <SubscribeResponse xmlns="http://sns.amazonaws.com/doc/2010-03-31/">
'     <SubscribeResult>
'         <SubscriptionArn>pending confirmation</SubscriptionArn>
'     </SubscribeResult>
'     <ResponseMetadata>
'         <RequestId>c5490a81-973b-5fa6-93dc-5bed689c212f</RequestId>
'     </ResponseMetadata>
' </SubscribeResponse>

outFile.Close