VBScript

Send SMS Text Message to Phone Number

See more Amazon SNS Examples

Uses Amazon SNS to send an SMS text message to a phone number.

See SNS Publish for more information.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sns.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sns.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sns"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","Publish")
' ----------------------------------------------------
' Please use your own phone number here for testing...
' ----------------------------------------------------
success = rest.AddQueryParam("PhoneNumber","+15551239999")
success = rest.AddQueryParam("Message","This is a test message from Amazon SNS")

responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    WScript.Quit
End If

' Examine the successful XML response.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())

' To get the MessageId
outFile.WriteLine("MessageId: " & xml.ChilkatPath("PublishResult|MessageId|*"))

' A sample successful response:
' <?xml version="1.0" encoding="utf-8"?>
' <PublishResponse xmlns="http://sns.amazonaws.com/doc/2010-03-31/">
'     <PublishResult>
'         <MessageId>5ffca506-6ff6-502c-bca3-f098971bcb9c</MessageId>
'     </PublishResult>
'     <ResponseMetadata>
'         <RequestId>6c815022-050e-5930-a7b4-05bcfde35280</RequestId>
'     </ResponseMetadata>
' </PublishResponse>

outFile.Close