(VBScript) SNS Publish (Send Message)

Sends a message to all of a topic's subscribed endpoints.

See SNS Publish for more information.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sns.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sns.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sns"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","Publish")
success = rest.AddQueryParam("TopicArn","arn:aws:sns:us-west-2:957491831129:chilkat")
' For subscribed email addresses, this is the subject of the email.
success = rest.AddQueryParam("Subject","Test Message from Amazon SNS")
success = rest.AddQueryParam("Message","This is a test message from Amazon SNS")

responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    WScript.Quit
End If

' Examine the successful XML response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
outFile.WriteLine(xml.GetXml())

' To get the MessageId
outFile.WriteLine("MessageId: " & xml.ChilkatPath("PublishResult|MessageId|*"))

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <PublishResponse xmlns="http://sns.amazonaws.com/doc/2010-03-31/">
'     <PublishResult>
'         <MessageId>5e135f2e-898d-5006-940a-0f43829c764b</MessageId>
'     </PublishResult>
'     <ResponseMetadata>
'         <RequestId>9adbf47d-9e07-5981-bb7f-a4609a167fcc</RequestId>
'     </ResponseMetadata>
' </PublishResponse>

outFile.Close