(VBScript) SMTP using SOCKS5, SOCKS4 Proxy

Demonstrates how to communicate with an SMTP server via a SOCKS4 or SOCKS5 proxy.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' To use a SOCKS4 or SOCKS5 proxy, simply set the following
' properties prior to making any calls that communicate with
' an SMTP server:
' The SOCKS hostname may be a domain name or 
' IP address:
mailman.SocksHostname = "www.mysocksproxyserver.com"
mailman.SocksPort = 1080
mailman.SocksUsername = "myProxyLogin"
mailman.SocksPassword = "myProxyPassword"
' Set the SOCKS version to 4 or 5 based on the version
' of the SOCKS proxy server:
mailman.SocksVersion = 5
' Note: SOCKS4 servers only support usernames without passwords.
' SOCKS5 servers support full login/password authentication.

' Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

' Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
success = email.AddTo("Chilkat Admin","admin@chilkatsoft.com")

' Call SendEmail to connect to the SMTP server and send.
' The connection (i.e. session) to the SMTP server remains
' open so that subsequent SendEmail calls may use the
' same connection.  
success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Some SMTP servers do not actually send the email until 
' the connection is closed.  In these cases, it is necessary to
' call CloseSmtpConnection for the mail to be  sent.  
' Most SMTP servers send the email immediately, and it is 
' not required to close the connection.  We'll close it here
' for the example:
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine("Connection to SMTP server not closed cleanly.")
End If

outFile.WriteLine("Mail Sent!")

outFile.Close