(VBScript) Send HTML Email with Attachments

Demonstrates how to send an HTML email with file attachments.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

mailman.SmtpHost = "smtp.my-starttls-mail-server.com"

mailman.SmtpUsername = "MY-SMTP-USERNAME"
mailman.SmtpPassword = "MY-SMTP-PASSWORD"

mailman.StartTLS = 1
mailman.SmtpPort = 587

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")
email.Subject = "Test SMTP API to Send HTML Email with Attachments"
email.From = "Joe Programmer <joe@my-starttls-mail-server.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

' Add a plain-text alternative body, which will likely never be seen.
' (It is shown if the receiving email client is incapable of displaying HTML email.)
success = email.AddPlainTextAlternativeBody("This is a plain-text alternative body...")

' Our HTML will include an image, so add the related image here.
contentIdStarfish = email.AddRelatedFile("qa_data/jpg/starfish.jpg")
If (email.LastMethodSuccess <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' The src attribute for the image tag is set to the contentIdStarfish:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbHtml = CreateObject("Chilkat.StringBuilder")
success = sbHtml.Append("<html><body><p>This is an HTML email with an embedded image.</p>")
success = sbHtml.Append("<p><img src=""cid:CONTENT_ID_STARFISH"" /></p></body></html>")
numReplacements = sbHtml.Replace("CONTENT_ID_STARFISH",contentIdStarfish)

success = email.AddHtmlAlternativeBody(sbHtml.GetAsString())

' Finally, add some attachments to the email.
' Add a file attachment.
success = email.AddFileAttachment2("qa_data/pdf/fishing.pdf","application/pdf")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' Add an attachment where the content is contained in a string.
content = "This is the content of the 2nd attached file."
success = email.AddStringAttachment("someText.txt",content)

' Send the HTML email.
success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine("Connection to SMTP server not closed cleanly.")
End If

outFile.WriteLine("HTML email with attachments sent!")

outFile.Close