VBScript

Send Signed Email using PFX File

Demonstrates how to send a signed email using a digital certificate w/ private key stored in a PFX file. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan")

' Set the SMTP server.
mailman.SmtpHost = "smtp.mymailserver.com"

' Create a new email object
set email = CreateObject("Chilkat.Email")

email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

' Indicate that the email should be sent signed.
email.SendSigned = 1

' Tell the mailman to use a PFX file as a source for locating
' the certificate and private key required for signing.
' The certificate chosen for signing will be the one that
' matches the sender's email address, which also has
' a private key.  All intermediate certs in the chain of 
' authentication, up to and including the root, will
' be included in the signature.
success = mailman.AddPfxSourceFile("/pfx_files/chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Signed email can be sent in two different ways.  
' In a multipart/signed email, the signature is attached as a separate MIME part.
' In an opaque email (signedData) the content of the email is encapsulated within the signature
' and the email is sent as "application/pkcs7-mime". 
' Either should be fine, but some receiving systems might require one or the other..
mailman.OpaqueSigning = 0

' Send a signed email.
success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
Else
    ' The LastErrorText property provides information
    ' even when successful.
    outFile.WriteLine(mailman.LastErrorText)
    outFile.WriteLine("Mail Sent!")
End If


outFile.Close