(VBScript) Send Email using office365 SMTP

Demonstrates how to send an email using Office365.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' Set the SMTP server to Office365's SMTP server.
' Note: Please be sure to double-check the SMTP settings
' with your provider or with the official Office365 documentation
' provided by Microsoft.  The required settings could change...
mailman.SmtpHost = "smtp.office365.com"
mailman.SmtpPort = 587
mailman.StartTLS = 1

' Set the SMTP login/password
mailman.SmtpUsername = "OFFICE365_USERNAME"
mailman.SmtpPassword = "OFFICE365_PASSWORD"

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "My Name <my_office365_email@example.com>"
success = email.AddTo("Chilkat Admin","admin@chilkatsoft.com")

' Call SendEmail to connect to the SMTP server and send.
' The connection (i.e. session) to the SMTP server remains
' open so that subsequent SendEmail calls may use the
' same connection.  
success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine("Connection to SMTP server not closed cleanly.")
End If

outFile.WriteLine("Mail Sent!")

outFile.Close