(VBScript) Find Certificate for Email Encryption

Demonstrates finding the recipient's certificate in the Windows certificate store and using it to send encrypted email.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' Set the SMTP server.
mailman.SmtpHost = "smtp.example.com"

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Joe <joe@example.com>"
' Emails are encrypted using the recipient's certificate.
recipientEmailAddr = "jane@example2.com"
success = email.AddTo("Jane",recipientEmailAddr)

' Indicate that the email is to be sent encrypted.
email.SendEncrypted = 1

' This example demonstrates finding the email encryption certificate
' on a Windows system where the certificate is stored in the Windows 
' certificate store.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
' The recipient's certificate is used to encrypt.
' (Because the recipient is the only one in possession of the private key to decrypt.)
success = cert.LoadByEmailAddress(recipientEmailAddr)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Specify the certificate to be used for encryption.
success = email.SetEncryptCert(cert)

success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
Else
    outFile.WriteLine("Encrypted Mail Sent!")
End If


outFile.Close