(VBScript) SharePoint User Authentication (Windows classic mode authentication)

Demonstrates how to achieve Windows classic mode authentication with SharePoint. This method uses NTLM to provide the Windows credentials. The example shows how to send a GET request that returns a JSON representation of all of a site’s lists.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For example, imagine our SharePoint endpoint is https://xyzoffice.mycompany.com/
' The SHAREPOINT_NTLM_DOMAIN would be "mycompany.com"
' The SHAREPOINT_HTTPS_DOMAIN would be "xyzoffice.mycompany.com"

' Also, the SHAREPOINT_USERNAME would be just the name, not a full email address.
' for example, "chilkat" instead of "chilkat@mycompany.com"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Provide the credentials:
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
' Tell Chilkat to use NTLM authentication.
http.NtlmAuth = 1

' Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJson = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb("https://SHAREPOINT_HTTPS_DOMAIN/_api/web/lists",sbJson)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.LoadSb(sbJson)
json.EmitCompact = 0

' This will emit the full JSON representation of all of a site's list.
outFile.WriteLine(json.Emit())

outFile.Close