VBScript

SharePoint Rest API using OAuth

See more OAuth2 Examples

Demonstrates how to get an OAuth2 access token for the SharePoint REST API. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' To further clarify, see OAuth 2.0 Authorization Flow

set oauth2 = CreateObject("Chilkat.OAuth2")

' The ListenPort should match the port in your localhost Reply URL of your Azure AD app.
' Your Reply URL must be exactly "http://localhost:LISTEN_PORT/"
'    * Do not use "https"
'    * Make sure the ending "/" is included.
'    * You may choose any port number that doesn't collide with anything else.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/TENANT_ID/oauth2/authorize"
oauth2.TokenEndpoint = "https://login.windows.net/TENANT_ID/oauth2/token?api-version=1.0"

' Replace these with actual values.
' Use the application ID
oauth2.ClientId = "CLIENT_ID"
' Use the password
oauth2.ClientSecret = "CLIENT_SECRET"

oauth2.CodeChallenge = 0

oauth2.Scope = "openid"
oauth2.Resource = "https://graph.microsoft.com/"

oauth2.IncludeNonce = 1
oauth2.ResponseMode = "form_post"
oauth2.ResponseType = "id_token+code"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Wait for the user to approve or deny authorization in the browser.
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect – The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response – The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    outFile.WriteLine("No response from the browser!")
    WScript.Quit
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success – OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied – OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure – OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    outFile.WriteLine("OAuth2 failed to complete.")
    outFile.WriteLine(oauth2.FailureInfo)
    WScript.Quit
End If

If (oauth2.AuthFlowState = 4) Then
    outFile.WriteLine("OAuth2 authorization was denied.")
    outFile.WriteLine(oauth2.AccessTokenResponse)
    WScript.Quit
End If

If (oauth2.AuthFlowState <> 3) Then
    outFile.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    WScript.Quit
End If

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("Access Token = " & oauth2.AccessToken)

outFile.Close