VBScript

SharePoint OAuth2 Client Credentials Authentication

Demonstrates how to authenticate with OAuth 2.0 using the client credentials grant type. This is for SharePoint Online which is the cloud-based service provided by Microsoft as part of Office 365. (Users access SharePoint Online through a web browser, and the service is hosted on Microsoft's servers.) VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Provide the information needed for Chilkat to automatically fetch the OAuth2.0 
' access token as needed.
set jsonOAuthCC = CreateObject("Chilkat.JsonObject")

' --------------------------------------------------------------------------------------------------------
' You'll need to have registered an app in Azure beforehand.
' See How to Create SharePoint App Registration for OAuth 2.0 Client Credentials
' --------------------------------------------------------------------------------------------------------

' Use the values from your App Registration in Azure.
success = jsonOAuthCC.UpdateString("client_id","CLIENT_ID")
success = jsonOAuthCC.UpdateString("client_secret","SECRET_VALUE")

' You'll always use this scope for client credentials, because the allowed actions
' are determined by the App Permissions defined when you registered the app in Azure.
success = jsonOAuthCC.UpdateString("scope","https://graph.microsoft.com/.default")

' The token endpoint includes your tenant ID. 
success = jsonOAuthCC.UpdateString("token_endpoint","https://login.microsoftonline.com/TENANT_ID/oauth2/v2.0/token")

' Provide the OAuth2 information. Chilkat will use this information to automatically fetch the OAuth2 access token as needed,
http.AuthToken = jsonOAuthCC.Emit()

' Get information about all SharePoint sites.
set sbJson = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb("https://graph.microsoft.com/v1.0/sites/getAllSites",sbJson)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

statusCode = http.LastStatus

outFile.WriteLine("Response status code = " & statusCode)

If (statusCode <> 200) Then
    outFile.WriteLine(sbJson.GetAsString())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

set jsonResp = CreateObject("Chilkat.JsonObject")
success = jsonResp.LoadSb(sbJson)
jsonResp.EmitCompact = 0

outFile.WriteLine(jsonResp.Emit())
outFile.WriteLine("Success.")

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

outFile.Close