(VBScript) SharePoint -- Get Server Form Digest Value

Demonstrates how to get a server form digest value to be placed in the X-RequestDigest HTTP request header for POST, PUT, MERGE, and DELETE requests. A form digest value is typically valid for 1800 seconds (i.e. 30 minutes). This example persists the value to a file, and only requests a new form digest value if the existing one is near expiration.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First, let's see if we already have a persisted form digest value
' that hasn't yet expired.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")

' My example code (below) persists the form digest XML in this format:
' 
' 	<savedFormDigestValue>
' 	<d:ExpireDateTime>2017-04-12T20:46:39Z</d:ExpireDateTime>
' 	<d:FormDigestValue>0x3059FFB920651834540F3E6792EA73F5746B302E953FF4E808E485DB1E6C2836C7CF924644995F092453B02A94DE14A7962674B7B16780AF16EAFB8C246BCDC7,12 Apr 2017 17:08:22 -0000</d:FormDigestValue>
' 	</savedFormDigestValue>
' 

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dtExpire = CreateObject("Chilkat.CkDateTime")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dtNow = CreateObject("Chilkat.CkDateTime")

formDigestXmlFile = "qa_data/sharepoint/savedFormDigestValue.xml"
If (fac.FileExists(formDigestXmlFile) = 1) Then

    success = xml.LoadXmlFile(formDigestXmlFile)

    ' Get the expire date/time
    success = dtExpire.SetFromTimestamp(xml.GetChildContent("d:ExpireDateTime"))

    ' Get the current date/time
    success = dtNow.SetFromCurrentSystemTime()

    ' Get both times as Unix time values
    tNow = dtNow.GetAsUnixTime(0)
    tExpire = dtExpire.GetAsUnixTime(0)

    ' If tNow >= tExpire, then fall through.
    ' Otherwise, just use the cached digest value.
    If (tNow < tExpire) Then
        outFile.WriteLine("Cached digest value is not yet expired.")
        outFile.WriteLine("X-RequestDigest: " & xml.GetChildContent("d:FormDigestValue"))
        WScript.Quit
    End If

End If

' If we got to this point, the cached digest value either does not exist, or expired.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication

' When creating, updating, and deleting SharePoint entities, we'll need
' to first get the server's form digest value to send in the X-RequestDigest header.
' This can be retrieved by making a POST request with an empty body to
' http://<site url>/_api/contextinfo and extracting the value of the
' d:FormDigestValue node in the XML that the contextinfo endpoint returns.

' Apparently, SharePoint needs an "Accept" request header equal to "application/xml",
' otherwise SharePoint will return an utterly incomprehensible and useless error message.
savedAccept = http.Accept
http.Accept = "application/xml"

' Note: The last argument ("utf-8") is meaningless here because the body is empty.
' resp is a Chilkat.HttpResponse
Set resp = http.PostXml("https://SHAREPOINT_HTTPS_DOMAIN/_api/contextinfo","","utf-8")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Restore the default Accept header
http.Accept = savedAccept

If (resp.StatusCode <> 200) Then
    ' A response status code not equal to 200 indicates failure.
    outFile.WriteLine("Response status code = " & resp.StatusCode)
    outFile.WriteLine("Response body:")
    outFile.WriteLine(resp.BodyStr)

    WScript.Quit
End If

success = xml.LoadXml(resp.BodyStr)

' The response XML looks like this:

' <?xml version="1.0" encoding="utf-8" ?>
' <d:GetContextWebInformation xmlns:d="http://schemas.microsoft.com/ado/2007/08/dataservices" xmlns:m="http://schemas.microsoft.com/ado/2007/08/dataservices/metadata" xmlns:georss="http://www.georss.org/georss" xmlns:gml="http://www.opengis.net/gml" m:type="SP.ContextWebInformation">
'     <d:FormDigestTimeoutSeconds m:type="Edm.Int32">1800</d:FormDigestTimeoutSeconds>
'     <d:FormDigestValue>0x3059FFB920651834540F3E6792EA73F5746B302E953FF4E808E485DB1E6C2836C7CF924644995F092453B02A94DE14A7962674B7B16780AF16EAFB8C246BCDC7,12 Apr 2017 17:08:22 -0000</d:FormDigestValue>
'     <d:LibraryVersion>15.0.4569.1000</d:LibraryVersion>
'     <d:SiteFullUrl>https://SHAREPOINT_HTTPS_DOMAIN</d:SiteFullUrl>
'     <d:SupportedSchemaVersions m:type="Collection(Edm.String)">
'         <d:element>14.0.0.0</d:element>
'         <d:element>15.0.0.0</d:element>
'     </d:SupportedSchemaVersions>
'     <d:WebFullUrl>https://SHAREPOINT_HTTPS_DOMAIN</d:WebFullUrl>
' </d:GetContextWebInformation>
' 

' Cache the digest value, and also an expiration time.  If this code is run again
' before the digest expires, we'll just get it from the file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml2 = CreateObject("Chilkat.Xml")

xml2.Tag = "savedFormDigestValue"
xml2.NewChild2 "d:FormDigestValue",xml.GetChildContent("d:FormDigestValue")

timeoutInSec = xml.GetChildIntValue("d:FormDigestTimeoutSeconds")
outFile.WriteLine("Timeout in seconds = " & timeoutInSec)

' Convert this to an expire timestamp.
' Let's make it expire 30 seconds prior to the actual timeout, just to be safe.
If (timeoutInSec > 30) Then
    timeoutInSec = timeoutInSec - 30
End If

success = dtExpire.SetFromCurrentSystemTime()
success = dtExpire.AddSeconds(timeoutInSec)
xml2.NewChild2 "d:ExpireDateTime",dtExpire.GetAsTimestamp(0)

' Persist the digest and expire time to a file.
success = xml2.SaveXml(formDigestXmlFile)

outFile.WriteLine("Here is the new form digest value:")
outFile.WriteLine("X-RequestDigest: " & xml.GetChildContent("d:FormDigestValue"))

outFile.Close