(VBScript) SharePoint -- Get File Metadata (File Size, Last-Modified Date/Time, etc.)

See more SharePoint Examples

Demonstrates how to get a file's metdata, which includes the file size, last-modified date/time, name, server relative URL, etc.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication

' Indicate that we want a JSON reply
http.Accept = "application/json;odata=verbose"
http.AcceptCharset = "utf-8"

url = "https://SHAREPOINT_HTTPS_DOMAIN/_api/web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')"

jsonReply = http.QuickGetStr(url)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Examine the file's metadata in JSON format.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(jsonReply)
json.EmitCompact = 0

' Make sure it was a success response, and that we really have metadata.
' If it was an error response, then the JSON is error information..
If (http.LastStatus <> 200) Then
    outFile.WriteLine(json.Emit())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

outFile.WriteLine(json.Emit())

outFile.WriteLine("--------")
outFile.WriteLine("Server relative URL: " & json.StringOf("d.ServerRelativeUrl"))

fileSize = json.IntOf("d.Length")
outFile.WriteLine("File Size = " & fileSize)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set lastmod = CreateObject("Chilkat.CkDateTime")
success = lastmod.SetFromTimestamp(json.StringOf("d.TimeLastModified"))

' Once we have the CkDateTime object, we can get the date/time in all sorts of formats:

' Get as a RFC822 GMT string:
bLocalTime = 0
outFile.WriteLine(lastmod.GetAsRfc822(bLocalTime))

' Get as an RFC822 string in the local timezone.
' (remember, the daylight savings that existed at the given time in the past is applied)
bLocalTime = 1
outFile.WriteLine(lastmod.GetAsRfc822(bLocalTime))

' Get as a 32-bit UNIX time (local or GMT..)
' The Unix time is number of seconds since the Epoch, 1970-01-01 00:00:00 +0000 (UTC). 
unixTime = lastmod.GetAsUnixTime(bLocalTime)
outFile.WriteLine("Unix time: " & unixTime)

' One can also get the as a "DtObj" object for accessing the individual
' parts of the date/time, such as month, day, year, hour, minute, etc.
' The DtObj can be obtained in the GMT or local timezone:
' dtObj is a Chilkat.DtObj
Set dtObj = lastmod.GetDtObj(bLocalTime)
If (lastmod.LastMethodSuccess = 0) Then
    outFile.WriteLine("This should never really happen!")
    WScript.Quit
End If

outFile.WriteLine(dtObj.Day & "-" & dtObj.Month & "-" & dtObj.Year & " " & dtObj.Hour & ":" & dtObj.Minute _
     & ":" & dtObj.Second)

' -------------------------------------------------
' The file's metadata look like this:

' { 
'   "d": { 
'     "__metadata": { 
'       "id": "Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')",
'       "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')",
'       "type": "SP.File"
'     },
'     "Author": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/Author"
'       }
'     },
'     "CheckedOutByUser": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/CheckedOutByUser"
'       }
'     },
'     "ListItemAllFields": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/ListItemAllFields"
'       }
'     },
'     "LockedByUser": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/LockedByUser"
'       }
'     },
'     "ModifiedBy": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/ModifiedBy"
'       }
'     },
'     "Versions": { 
'       "__deferred": { 
'         "uri": "https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/GetFileByServerRelativeUrl('/Documents/VCAC-document.docx')/Versions"
'       }
'     },
'     "CheckInComment": "",
'     "CheckOutType": 2,
'     "ContentTag": "{E2F05E75-B3EF-4826-8284-E572D3628A7D},9,10",
'     "CustomizedPageStatus": 0,
'     "ETag": "\"{E2F05E75-B3EF-4826-8284-E572D3628A7D},9\"",
'     "Exists": true,
'     "Length": "21082",
'     "Level": 2,
'     "MajorVersion": 0,
'     "MinorVersion": 3,
'     "Name": "VCAC-document.docx",
'     "ServerRelativeUrl": "/Documents/VCAC-document.docx",
'     "TimeCreated": "2016-03-04T12:38:01Z",
'     "TimeLastModified": "2017-01-16T04:44:31Z",
'     "Title": "",
'     "UIVersion": 3,
'     "UIVersionLabel": "0.3"
'   }
' }
' 

outFile.Close