(VBScript) SFTP use Cert's Private Key for Authentication (Windows)

Demonstrates how to use the private key of a pre-installed certificate (on Windows) for SFTP authentication. The certificate's private key must be marked as "exportable" when originally installed.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")

' Load the certificate from the Windows certificate store
success = cert.LoadByCommonName("my_cert_common_name")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Get the private key.  
' privKey is a Chilkat.PrivateKey
Set privKey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

privKeyPem = privKey.GetPkcs8Pem()
If (privKey.LastMethodSuccess = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SshKey")
set sshKey = CreateObject("Chilkat.SshKey")
success = sshKey.FromOpenSshPrivateKey(privKeyPem)
If (success = 0) Then
    outFile.WriteLine(sshKey.LastErrorText)
    WScript.Quit
End If

' Connect to an SSH/SFTP server
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")
success = sftp.Connect("sftp.example.com",22)
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server using a username + private key.
' (The private key serves as the password.  The username identifies
' the SSH user account on the server.)
success = sftp.AuthenticatePk("mySshLogin",sshKey)
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("OK, the connection and authentication with the SSH server is completed.")

' This example is only to show the connection + authentication using a private key associated with a certificate in the Windows certificate store...

outFile.Close