(VBScript) SFTP Synchronize Directory Tree - Download

Demonstrates how to download files to synchronize a local directory tree with a remote directory tree. The SyncTreeDownload method recursively descends the remote directory tree and downloads files based on existence, last-mod date/time and/or size differences.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

success = sftp.Connect("my-ssh-server.com",22)
If (success = 1) Then
    success = sftp.AuthenticatePw("mySshLogin","mySshPassword")
End If

If (success = 1) Then
    success = sftp.InitializeSftp()
End If

If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Synchronize the remote directory tree rooted at "syncDownloadTest/xml"
' with the local directory tree rooted at "qa_output"
' Both directories are relative paths.  The remote directory
' is relative to the HOME directory of the SSH user account.
' The local directory is relative to the current working directory of the process.
' It is also possible to use absolute paths.

remoteDir = "syncDownloadTest/xml"
localDir = "qa_output"

' Possible modes that can be passed to the SyncTreeDownload method are:
' mode=0: Download all files
' mode=1: Download all files that do not exist on the local filesystem.
' mode=2: Download newer or non-existant files.
' mode=3: Download only newer files. If a file does not already exist on the local filesystem, it is not downloaded from the server.
' mode=5: Download only missing files or files with size differences.
' mode=6: Same as mode 5, but also download newer files.
' mode=99: Do not download files, but instead delete remote files that do not exist locally.

' This example will use mode 6 to download missing, newer, or files with size differences.
mode = 6
' This example will turn on recursion to synchronize the entire tree. 
' Recursion can be turned off to synchronize the files of a single directory.
recursive = 1
success = sftp.SyncTreeDownload(remoteDir,localDir,mode,recursive)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close