(VBScript) SFTP Sync Download Tree w/ Must-Match Filename Constraints

Demonstrates how synchronize a directory tree in the download direction, but only download files matching a set of wildcard filenames.

Note: This example requires Chilkat v9.5.0.76 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

success = sftp.Connect("my-ssh-server.com",22)
If (success = 1) Then
    success = sftp.AuthenticatePw("mySshLogin","mySshPassword")
End If

If (success = 1) Then
    success = sftp.InitializeSftp()
End If

If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Possible synchronization modes are:
' mode=0: Download all files
' mode=1: Download all files that do not exist on the local filesystem.
' mode=2: Download newer or non-existant files.
' mode=3: Download only newer files. If a file does not already exist on the local filesystem, it is not downloaded from the server.
' mode=5: Download only missing files or files with size differences.
' mode=6: Same as mode 5, but also download newer files.

' This example will download all files, but only those files having filenames
' that match *.gif and *.eml

' Imagine our remote directory tree has these files and directories:

' 	accentedLatin1.txt
' 	accentedUtf8.txt
' 	alice.key
' 	anter_cert.pem
' 	chiliPepper.gif
' 	helloWorld.pdf
' 	abc/chiliPepper.gif
' 	abc/ghk/
' 	data/chiliPepper.gif
' 	data/xyz/dkimHtmlBody.txt
' 	data/xyz/dkimVerifyTest.eml
' 	data/xyz/emailForCreateDsn.eml
' 	text/frenchUtf8.txt
' 	text/helloWorld.txt
' 	text/PolishEmailBody.txt
' 	text/something/

' Indicate that we only want to create auto-create local directories (if needed)
' for the files that are actually downloaded.  If SyncCreateAllLocalDirs remains
' 1, then the corresponding local directory is created for each remote directory
' traversed regardless of whether files within are downloaded.
sftp.SyncCreateAllLocalDirs = 0

sftp.SyncMustMatch = "*.eml; *.gif"

remoteDir = "syncDownloadTest/someDir"
localDir = "qa_output"
mode = 0
recursive = 1
success = sftp.SyncTreeDownload(remoteDir,localDir,mode,recursive)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' The following files were downloaded:

' chiliPepper.gif
' abc/chiliPepper.gif
' data/chiliPepper.gif
' data/xyz/dkimVerifyTest.eml
' data/xyz/emailForCreateDsn.eml

outFile.WriteLine("Success.")

outFile.Close