(VBScript) SFTP Resume Upload

Demonstrates how to resume an SFTP upload to an SSH server. The ResumeUploadFileByName method checks the size of the file on the remote server and begins uploading from the appropriate position in the local file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Upload from the local file to the SSH server.
' Important -- the remote filepath is the 1st argument,
' the local filepath is the 2nd argument;
remoteFilePath = "hamlet.xml"
localFilePath = "c:/temp/hamlet.xml"

' The ResumeUploadFileByName method first gets the size
' of the partial file on the server and then begins uploading
' from the appropriate point in the local file.
' If the remote file does not exist or is 0-length, this
' method is equivalent to UploadFileByName.
' If the remote file is already equal to or larger in size
' than the local file, then nothing more is uploaded.
success = sftp.ResumeUploadFileByName(remoteFilePath,localFilePath)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close