(VBScript) Co:Z SFTP Binary File Download (from z/OS IBM Mainframe)

Demonstrates how to download a binary file, such as a .zip, from a Co:Z SFTP server on a z/OS IBM Mainframe.

Note: This requires Chilkat v9.5.0.76 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Connect to the SSH server.  
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' To download a binary file from the Co:Z SFTP server, 
' we must switch to binary mode in the following unconventional way.
' We pretend to fetch a directory listing for "/+mode=binary"
' This has the effect of putting the server in binary mode for transfers.
handle = sftp.OpenDir("/+mode=binary")
If (sftp.LastMethodSuccess <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Download the "directory listing" (but it's not actually a directory listing, and we'll just discard it.)
' dirListing is a Chilkat.SFtpDir
Set dirListing = sftp.ReadDir(handle)
If (sftp.LastMethodSuccess <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Close the directory handle:
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Download the binary file:
localFilePath = "c:/temp/test.zip"
remoteFilePath = "test.zip"
success = sftp.DownloadFileByName(remoteFilePath,localFilePath)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close