(VBScript) SFTP Get Size of File on Server

See more SFTP Examples

Demonstrates how to get the size of an existing file on the server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Assuming we know the file size won't be too large, we get the size as a 32-bit integer.
' For SFTP, the remote file path is always either a path relative to the HOME directory of the user account, or an absolute path on the server.
bFollowLinks = 1
bIsHandle = 0
fileSize = sftp.GetFileSize32("someDir/someFile.dat",bFollowLinks,bIsHandle)
If (fileSize < 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("file size = " & fileSize)

' If the file size might be too large for a 32-bit signed integer, then get the size as a decimal string.
' You can convert the string to a 64-bit integer in your programming language.
fileSizeStr = sftp.GetFileSizeStr("someDir/someFile.dat",bFollowLinks,bIsHandle)
If (sftp.LastMethodSuccess = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("file size = " & fileSizeStr)

' You can alternatively get the size with an open file handle.
handle = sftp.OpenFile("someDir/someFile.dat","readOnly","openExisting")
If (sftp.LastMethodSuccess <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Get the size using the handle.
bIsHandle = 1
fileSize = sftp.GetFileSize32("someDir/someFile.dat",bFollowLinks,bIsHandle)
If (fileSize < 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("file size = " & fileSize)

' -----------------------------------------------------------------------------
' Don't forget to close the file handle.
' Otherwise open handles will accumulate on the server until eventually a limit
' is reached and the server will fail on a call to OpenFile.
' -----------------------------------------------------------------------------

' Close the file.
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If


outFile.Close