VBScript

SFTP Delete Directory

See more SFTP Examples

Demonstrates how to delete a directory on the remote SFTP server. The directory should be empty prior to deleting. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set sftp = CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Delete a directory on the server.
' The directory should be empty prior to deleting.
success = sftp.RemoveDir("abc123")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Directory Deleted!")

outFile.Close