(VBScript) SFTP Create Directory

Demonstrates how to create a new directory on the remote SFTP server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Important: It is helpful to send the contents of the
' sftp.LastErrorText property when requesting support.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 15000
sftp.IdleTimeoutMs = 15000

' Connect to the SSH server.  
success = sftp.Connect("sftp.example.com",22)
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Create a new directory:
success = sftp.CreateDir("myNewDir")
If (success <> 1) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close