(VBScript) AWS Transfer for SFTP (Amazon S3)

Once you've setup your AWS Transfer for SFTP in the AWS Console, interacting with it is no different than any other SSH/SFTP server. AWS will provide a private key in PEM format. It is used for authentication (instead of a password).

For more information, see https://docs.aws.amazon.com/transfer/latest/userguide/getting-started-use-the-service.html

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = CreateObject("Chilkat.SFtp")

' Connect to the AWS SFTP server.
' Change the domain to your value.
domain = "s-123456df999999fab.server.transfer.eu-west-2.amazonaws.com"
port = 22
success = sftp.Connect(domain,port)
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Load your AWS SFTP private key PEM file..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SshKey")
set sshKey = CreateObject("Chilkat.SshKey")
keyText = sshKey.LoadText("qa_data/pem/s3_sftp_privateKey.pem")
If (sshKey.LastMethodSuccess <> 1) Then
    outFile.WriteLine(sshKey.LastErrorText)
    WScript.Quit
End If

success = sshKey.FromOpenSshPrivateKey(keyText)
If (success = 0) Then
    outFile.WriteLine(sshKey.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server using the private key.
success = sftp.AuthenticatePk("myUsername",sshKey)
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

' Upload from the local file to the SSH server.
' Important -- the remote filepath is the 1st argument,
' the local filepath is the 2nd argument;
remoteFilePath = "hamlet.xml"
localFilePath = "c:/temp/hamlet.xml"

success = sftp.UploadFileByName(remoteFilePath,localFilePath)
If (success = 0) Then
    outFile.WriteLine(sftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close