VBScript

ScMinidriver - List Certificates on a Smart Card or USB Token

See more ScMinidriver Examples

Gets a list of certificates contained on a smart card or USB token. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set scmd = CreateObject("Chilkat.ScMinidriver")

' Reader names (smart card readers or USB tokens) can be discovered
' via PCSC List Readers or PCSC Find Smart Cards
readerName = "SCM Microsystems Inc. SCR33x USB Smart Card Reader 0"
success = scmd.AcquireContext(readerName)
If (success = 0) Then
    outFile.WriteLine(scmd.LastErrorText)
    WScript.Quit
End If

set stCerts = CreateObject("Chilkat.StringTable")

' We can choose one of the following items of information to get for each certificate:
' "subjectDN" -- Return the full distinguished name of the cert.
' "subjectDN_withTags" -- Same as above, but in a format that includes the subject part tags, such as the "CN=" in "CN=something"
' "subjectCN" -- Return just the common name part of the certificate's subject.
' "serial" -- Return the certificate serial number.
' "serial:issuerCN" -- return the certificate serial number + the issuer's common name, delimited with a colon char.
certPart = "subjectCN"

success = scmd.ListCerts(certPart,stCerts)
If (success = 0) Then
    outFile.WriteLine(scmd.LastErrorText)
    WScript.Quit
End If

numCerts = stCerts.Count
i = 0
Do While i < numCerts
    outFile.WriteLine(i & ": " & stCerts.StringAt(i))
    i = i + 1
Loop

' Delete the context when finished with the card.
success = scmd.DeleteContext()
If (success = 0) Then
    outFile.WriteLine(scmd.LastErrorText)
End If


outFile.Close