VBScript
SOAP Request to fseservicetest.sanita.finanze.it with Smart Card Authentication (TS-CNS Italian Card)

Demonstrates sending a SOAP request to fseservicetest.sanita.finanze.it with Smart Card (TS-CNS Italian Card).
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")
set xml = CreateObject("Chilkat.Xml")

success = 0

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' Create the SOAP envelope...
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:stat","http://statoconsensirichiesta.xsd.fse.ini.finanze.it")
success = xml.AddAttribute("xmlns:tip","http://tipodatistatoconsensi.xsd.fse.ini.finanze.it")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoUtente","XXXXXXAAABBBCCC"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:pinCode","..."
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoOrganizzazione","999"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:StrutturaUtente","123456789"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:RuoloUtente","ZZZ"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:ContestoOperativo",""
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoAssistitoGenitoreTutore",""
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:PresaInCarico","true"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:TipoAttivita","READ"
xml.UpdateChildContent "soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoAssistitoConsenso","ABCDEFGHIJKLM"
soapEnvelope = xml.GetXml()

domain = "fseservicetest.sanita.finanze.it"
path = "/FseInsServicesWeb/services/fseStatoConsensi"

set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.SendCharset = 0
req.AddHeader "Content-Type","application/soap+xml; charset=utf-8"
req.Path = path
success = req.LoadBodyFromString(soapEnvelope,"utf-8")

' Load the default certificate from the smartcard currently in the reader.
' (This assumes only one reader with one smartcard containing one certificate.
' If the situation is more complex, you can do it with Chilkat, but it requires
' using the Chilkat certificate store object to get the desired certificate
' from the desired smart card.)
' 
' Note: This is for Windows-only.
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromSmartcard("")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Tell the Chilkat HTTP object to use the certificate for client authentication.
success = http.SetSslClientCert(cert)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

http.TlsVersion = "TLS 1.1"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSReq(domain,443,1,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set xmlResp = CreateObject("Chilkat.Xml")
success = xmlResp.LoadXml(resp.BodyStr)
outFile.WriteLine(xmlResp.GetXml())

outFile.Close