VBScript

S3 Upload with Transfer Acceleration

See more Amazon S3 Examples

Demonstrates how to upload from a pre-signed URL with transfer acceleration. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

http.AwsAccessKey = "AWS_ACCESS_KEY"
http.AwsSecretKey = "AWS_SECRET_KEY"

' Make sure to set your AWS region correctly
http.AwsRegion = "us-east-1"
bucketName = "chilkat200"
objectName = "starfish/starfish.jpg"
awsService = "s3"
httpVerb = "PUT"

' To use S3 acceleration, we simply set the AwsEndpoint to "s3-accelerate.amazonaws.com".
' Note: You must enable transfer acceleration on your bucket.  Acceleration incurs a higher cost.
http.AwsEndpoint = "s3-accelerate.amazonaws.com"

' The signed URL will be valid for this number of seconds:
numSecondsValid = 86400

' Choose between a URL beginning with "http://" or "https://"...
bUseHttps = 1

' Generate the pre-signed URL that will use s3-accelerate.amazonaws.com
preSignedUrl = http.S3_GenPresignedUrl(httpVerb,bUseHttps,bucketName,objectName,numSecondsValid,awsService)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' The following URL can be copy-and-pasted into a browser..
outFile.WriteLine("Presigned URL for Upload: " & preSignedUrl)

' Here's an example of a pre-signed URL
' 
' http://chilkat200.s3-accelerate.amazonaws.com/starfish/starfish.jpg?X-Amz-Algorithm=AWS4-HMAC-SHA256&X-Amz-Credential=AKIAIBJLOVZVXAU2AFUA%2F20200623%2Fus-east-1%2Fs3%2Faws4_request&X-Amz-Date=20200623T234049Z&X-Amz-Expires=86400&X-Amz-SignedHeaders=host&X-Amz-Signature=xxxxxeaea071178d772856c0a4e4c0114a8d9992f0d0812955e490d0exxxxxxx
' 

' Upload a local file using the pre-signed URL.
' (Chilkat provides other methods to upload file data directly from binary or text data in memory.)
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpFile("PUT",preSignedUrl,"qa_data/jpg/starfish.jpg","image/jpg",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status code = " & resp.StatusCode)
outFile.WriteLine("response body size: " & resp.ContentLength)
If (resp.ContentLength > 0) Then
    outFile.WriteLine("response body:")
    outFile.WriteLine(resp.BodyStr)
End If


outFile.Close